FP8.s - virtualagc - Project Hosting on Google Code

r258

Source path: svn/ trunk/ FP8/ FP8.s

# Copyright:	Public domain.
# Filename:	FP8.s
# Purpose:	This is the Apollo lunar module's firmware for the 
#		Abort Guidance System (AGS).  This is Flight Program 8.
# Assembler:	yaLEMAP
# Contact:	Ron Burkey <info@sandroid.org>.
# Website:	www.ibiblio.org/apollo/yaAGS.html
# Reference:	http://www.ibiblio.org/apollo/Pultorak_files/FP8Listing.pdf.
# Mod history:	2005-01-15 RSB	Began.
#		2005-01-17 RSB	Data entry complete, but not debugged.
#		2005-01-18 RSB	As of yesterday, this assembled with
#				86 fatal errors.  These have all been
#				repaired.  Lots of other stuff fixed too.
#				I know know that the addresses and 
#				opcodes at the ends of each page are 
#				correct.  However, the checksums are
#				still wrong, so the next step is to
#				proceed with a binary comparison.
#		2005-01-18 RSB	Fully debugged and ready to go.
#				It has been completely proofed against
#				the binary in the scanned assembly
#				listing, and the checksums are correct.
#				(Of course, it could always use more 
#				proofing if somebody wanted to do it.
#				Particularly the program comments.)
#		2005-05-14 RSB	Corrected website reference above.
#		2005-06-12 RSB	Fixed comments on p. 117.
#
# The contents have been taken (by means of manual data entry) from 
# an assembly listing of Flight Program 8 scanned by John Pultorak from
# a physical copy preserved by supplied by Davis Peticolas.  (The WWW link
# for the scan is referenced above.)
#
# This file contains the entire source code for FP8.  I have not split the
# source code into many smaller chunks as has been done for AGC source code.
# The page references are to the scanned PDF of the assembly listing, but 
# the page markings on the physical copy match the PDF pages.  In addition 
# to the comments containing the page references, I've also added some 
# blank lines for readability.  So don't expect the line number in the 
# scanned version to match the line numbers in an assembly listing created
# by processing this source file with the yaLEMAP cross-assembler.

# Page 1
# FLIGHT PROGRAM 8 -- LM AGS FP8 S03 4039 -- 12/18/70
#     LM ABORT ELECTRONICS ASSEMBLY
#
#		SCRATCH PAD STORAGE
	ORG	0000
TS0	DEC	0
TS1	DEC	0
TS2	DEC	0
TS3	DEC	0
TS4	DEC	0
TS5	DEC	0
TS6	DEC	0
TS7	DEC	0
TS10	DEC	0
TS11	DEC	0
TS12	DEC	0
TS13	DEC	0
TS14	DEC	0
TS15	DEC	0
TS16	DEC	0
TS17	DEC	0
SREX3	DEC	0
SREX2	DEC	0
SREX1	DEC	0
SREX	DEC	0
TVARBR	DEC	0		# TEMP STORE FOR CK SUM.
	TRA	RETURN		# SERV ROUT, STARTUP
#
#		TAPE LOAD STARTUP CHECKSUM
#
SF	OUT	6402		# DEDA INPUT SCALE FACTOR
OCTF	INP	2040		# DEDA OCTAL INPUT
#
#		THE NEXT 16 LOCATIONS ARE SHARED
#		WITH A RR FILTER TEMPORARY MATRIX
#
U2X	ALS	1		# B1	UNIT RADIAL VECTOR TO
U2Y	TMI	*+2		# B1	TRIAL RENDEZ PT.
U2Z	TRA	*-3		# B1

# Page 2
D11	EQU	U2X		# 	RADAR TEMP. MATRIX (16 LOC)
VFX	EQU	U2X		# 	BRAKING VEL VECTOR AT 13.
C2	DLY	*+1		# B1	RENDEZ ANGLE SINE
V1X	OUT	7012		# B1	HORIZ UNIT VECTOR
V1Y	INP	6200
V1Z	CLZ	SUM
DLSC	CLA	V2Z		#	DOWNLINK SHIFT COUNTER
W1X	STO	TVARBR		# B1	U1 X V1
D31	EQU	W1X
W1Y	CLZ	WRDCNT
W1Z	TSQ	TVARBR
SI	ADZ	SUM		# B0 	E(SIN(E0))
RD2DOT	STO	SUM		# B7	DESIRED RADIAL ACCEL
YD2DOT	CLA	TVARBR		# B7	DESIRED OUT-OF-PLANE ACCEL
TSEX	SUB	CLAFR		#	EXIT FROM NORTON
SIDELL	TMI	U1X		# B1	SIN DELTA L
V6X	CLZ	SUM 		# B13	TEMP STORAGE FOR TPI QUANT
V6Y	TMI	*+3
V6Z	SUB	1B17
DQSX	EQU	V6X		# 	ACCUM VEL IN XDV
CODELL	TMI	EXIT40		# B1	COS DELTA L
WCX	CLA	10B4		# B1	UNIT VECTOR NORMAL
WCY	STO	S12		# 	TO CSM ORBIT
WCZ 	OUT	6410
TMPBR	TRA	SINITC		#	TEMP BRANCH STORE
U1X	CLZ	WRDCNT		# B1	LEM UNIT RAD VECTGOR
U1Y	ADD	1B17
U1Z	STO	WRDCNT
BRANCH	SUB	1B11		#	GUIDANCE BRANCH
V2X	TMI	W1Z		# B1	HORZ UNIT VECTOR AT
V2Y	DLY	W1Y		#	RENDEZ POINT
V2Z	CLA	0206
VGX	EQU	V2X		#	VEL TO GAIN VECTOR AT L3
#
#	END OF TAPE LOAD CHECKSUM PROGRAM
#
AT	DEC	0B7

# Page 3
EX	DEC	0B2		#	ATTITUDE ERRORS.
EY	DEC	0
EZ	DEC	0
X3	DEC	0B0		#	XFR ORB PARAM.
TR3	EQU	X3		#	ADDRESS OF RESULT FOR MXM
DVXM1	DEC	0B1		#	BODY DELTA VS
DVYM1	DEC	0		# 	PREVIOUS CYCLE.
DVZM1	DEC	0
NI	DEC	0B-9		#	PREDICTION ANGULAR FREQUENCY
NE	EQU	NI		# 	CSM PRED. ANGULAR FREQ.
TR8	EQU	NI		#	RADAR TEMP.
VD2X	DEC	0B2		# 	DELTA V EXP LS
VD2Y	DEC	0
VD2Z	DEC	0
CI	DEC	0B0		#	E(COS(E0))
TR1	EQU	CI		# 	ADDR. OF 1ST MATRIX FOR MXM
DRX	DEC	0B14		#	LRM POS REMAINDERS
DRY	DEC	0
DRZ	DEC	0
THEP	DEC	0		#	PGNS THETA IN COUNTS.
DIGX	DEC	0B7		# 	PREDICTED CHANGE IN
DIGY	DEC	0		#	INTEGRATED GRAVITY.
DIGZ	DEC	0
PSIP	DEC	0		#	PGNS PSI IN COUNTS.
GXDT	DEC	0B7		#	GRAVITY TIMES MAJOR
GYDT	DEC	0
GZDT	DEC	0
PHIP	DEC	0		#	PGNS PHI IN COUNTS.
DVSX	DEC	0
DVSY	DEC	0
DVSZ	DEC	0
SIGA	DEC	0B1		# 	SIN FDAI GAMMA.
RRX	DEC	0B23		# 	COMPUTED LM-CSM RANGE
RRY	DEC	0
RRZ	DEC	0
COGA	DEC	0B1		#	COS FDAI GAMMA.
A11	DEC	1.0B1		#	XB DIRECTION COSINES.

# Page 4
A12	DEC	0
A13	DEC	0
TS8	DEC	0
A31	DEC	0		#	ZB DIRECTION COSINES
A32	DEC	0
A33	DEC	1.0B1
SUM	DEC	0		# 	RUNNING MEMORY SUM
A21	DEC	0		#	YB DIRECTION COSINES
A22	DEC	1.0B1
A23	DEC	0
X4	DEC	0B0		#	XFR ORB PARAM.
VHSQ	EQU	X4		# 0B26	VH SQUARED
TR2	EQU	X4		#	ADDR. OF 2ND MATRIX FOR MXM
E1	DEC	0		#	-6 OR -9 XB NORM ERROR
E3	DEC	0		#	ZB NORMALITY ERROR.
E13	DEC	0		#	XB,ZB ORTHOG ERROR.
DEL10	DEC	0		#	TPI LOGIC FLAG
DA11	DEC	0B-5		#	DIR COSINE REMAINDERS
DA12	DEC	0
DA13	DEC	0
WRDCNT	DEC	0		#	CKSUM WORD COUNT
DA31	DEC	0
DA32	DEC	0
DA33	DEC	0
DEL44	DEC	0		#	RADAR CODE WORD RESET FLAG
A11D	DEC	0B1		#	XD DIRECTION COSINES.
A12D	DEC	0
A13D	DEC	0
	DEC	0		#	** UNUSED -- INDEXED BY A11D **
A31D	DEC	0B1		#	ZD DIRECTION COSINES.
A32D	DEC	0
A33D	DEC	0
MU17	DEC	0B3		#	RADAR FILTER ENTRY COUNTER
P	DEC	0B23		#	TRIAL SEMI-PARAMETER
ALPHA	DEC	0B23		#	XFR ORBIT SEMI-MAJOR AXIS
Q1	DEC	0B23		#	XFR ORBIT PERILUNE
ESQ	EQU	Q1

# Page 5
AI	DEC	0B23		#	PRED. SEMI-MAJOR AXIS
AE	EQU	AI		#	CSM PRED. SEMI-MAJOR AXIS
R5X	DEC	0B23		#	LM PRED POS AHEAD TDEL
R5Y	DEC	0
R5Z	DEC	0
AL	DEC	0B23		#	LM PRED. SEMI-MAJOR AXIS
REX	DEC	0B23		#	CSM EPOCH POSITION
REY	DEC	0
REZ	DEC	0
RT	DEC	0B23		#	CSM PRED POS. MAG.
R0X	DEC	0B23		#	PRED EPOCH POS VECTOR
R0Y	DEC	0
#	SEE REAR OF LISTING FOR CHECKSUM
#	Note that the CHECKSUM pseudo-op is not defined in the AGS
#	programmer's manual.  I have decided for the purposes of 
#	implementing yaLEMAT that the following syntax will be
#	used.  It means that the cross-assembler will compute a
#	checksum of the address range 0207-1004 (octal), and will
#	store it right here.
	CHECKSUM RANGE 0207-1004
R0Z	DEFINE	0206
R0	DEC	0B23		# 	PRED EPOCH POS. MAG.
C11	EQU	P		#	RADAR TEMP. MATRIX
C12	EQU	ALPHA
C13	EQU	Q1
C14	EQU	AI
C21	EQU	R5X
C22	EQU	R5Y
C23	EQU	R5Z
C24	EQU	AL
C31	EQU	REX
C32	EQU	REY
C33	EQU	REZ
C34	EQU	RT
C41	EQU	R0X
C42	EQU	R0Y
C43	EQU	R0Z
C44	EQU	R0
R	DEC	0B23		#	LM POS MAGNITUDE
Y	DEC	0B23		#	OUT OF PLANE POSITION
PP	DEC	0B23		#	P PRIME/EXIT FOR MXM
POUTFS	DEC	7.684096E4B23	#	MAX P DISPLAYABLE
POUT	DEC	0		#	DISPLAY POSITION.


# Page 6
DPOUT	DEC	0		# 	DISPLAY POSITION INCREMENT.
2K3	DEC	1048576.B23	#	QL SET ON O.F.
2K14	DEC	5.E4B23		#	INITIAL P PERTURBATION
RIX	DEC	0B23		#	ELLIPSE PRED POS OUTPUT
RIY	DEC	0
RIZ	DEC	0
DELR1	EQU	RIX		#	MEASURED MINUS COMPUTED RANGE
DELR3	EQU	RIY		# B23
DELR2	EQU	RIZ
25J	DEC	0B23		#	DEDA ALTITUDE UPDATE
7J	DEC	6042736B23	#	TERM IN AL(O.I.)
8J	DEC	2940243B23	#	TERM IN AL(O.I) LOWER LIMIT
10J	DEC	6046910B23	#	RETARGET VALUE FOR 7J
4K5	DEC	5735200B23	#	NOMINAL BURNOUT ALTITUDE
2K19	DEC	5.E5B23		#	DELTA P LIMITER
5J	DEC	5.697785E6B23	#	LANDING SITE RADIUS
16J	DEC	60000B23	#	ORBIT INSERTION ALTITUDE
21J	DEC	25000B23	#	PITCH STEERING ALT THRESHOLD
RRSX	DEC	0B23		#	CALCULATED RANGE AT TIME
RRSY	DEC	0		#	OF RADAR RANGE MEASUREMENT.
RRSZ	DEC	0
6K11	DEC	0.318310B0	#	1/PI
#
#	INITIALIZE DATA FROM DOWNLINK ADDRESSES
#		LOCATIONS 0240-0257 USED
1J1	DEC	0B23		#	LM EPHEMERIS POS
1J2	DEC	0
1J3	DEC	0
	DEC	0
2J1	DEC	0		# 	CSM EPHEMERIS POS
2J2	DEC	0
2J3	DEC	0
	DEC	0
	DEC	0
	DEC	0
	DEC	0
	DEC	0
	
# Page 7
1J7	DEC	0B18		#	LM EPOCH TIME
1J7LS	DEC	0B1
	DEC	0
	DEC	0
THETAR	EQU	2J3+4		#	RADAR ANTENNA TRUNNION ANGLE
BETAR	EQU	2J3+5		#	RADAR ANTENNA SHAFT ANGLE
RM	EQU	1J7		#	RADAR RAW RANGE INPUT
RMDOT	EQU	1J7+1		# 	RADAR RANGE RATE INPUT
DEL46	EQU	1J7+2		#	RADAR COMPOSITE WORD
1J4	DEC	0B13		#	LM EPHEMERIS VEL
1J5	DEC	0
1J6	DEC	0
VPY	DEC	0B13		#	OUT-OF-PLANE VELOCITY
2J4	DEC	0		#	CSM EPHEMERIS VEL
2J5	DEC	0
2J6	DEC	0
5K18	DEC	-.1B-2		#	RD3DOT LOWER LIMIT
VY0	DEC	0B13		#	LM OUT-OF-PLANE VEL
VY0FS	DEC	200B13		#	MAX VY0 DISPLAYABLE
2J7	DEC	0		#	CSM EPOCH TIME
2J7LS	DEC	0
7K1	DEC	30B18		#	TIG TIME BIAS
1J	DEC	0B18		#	NOMINAL TPI TIME (CSI)
6K5	DEC	-.73B0		#	Y-POSITION FILTER WEIGHT
XI	DEC	0B3		#	Z-AXIS/LOCAL HORIZ ANGLE
A31BD	DEC	0B1		#	UNIT VECTOR (LM-CSM)
A32BD	DEC	0
A33BD	DEC	0
TLOS	DEC	0B3		#	DXFR LOS COMPUTED
THETAF	EQU	TLOS		#	LM-CSM CENTRAL ANG AT CSI/CDH
3K4	DEC	.17365B1	#	CENTRAL ANGLE LIMIT ON TPI
12J	DEC	-.299904B3	#	PHASE ANGLE LIMIT FOR RETARGET
4J	DEC	0B13		#	TIME OF NODE PRIOR TO RENDEZ
6J	DEC	2580.0B13	#	DESIRED TRANSFER TIME
TDEL	DEC	0B13		#	TIME TIL NEXT MANEUVER
TR	DEC	0B13		#	TIME TIL RENDEZVOUS
3J	DEC	0B13		#	TARGET OFFSET TIME

# Page 8
6K12	DEC	9.38B4		#	RAW RADAR AT 18 TO FT. AT 22
DELRP	DEC	0B23		#	DIFF. ALT. AT TIG(CSI-CDH)
QA	DEC	0B23		#	LM APOFOCUS ALTITUDE
18J	DEC	0B22		#	MEASURED RADAR RANGE
RR	DEC	0B22		#	COMPUTED RANGE
READP	DEC	0
ENTERP	DEC	0
HOLDP	DEC	0
CLEARP	DEC	0
HMF	DEC	0
#		START OF TELEMETRY LIST
RMF	DEC	0		#	READOUT MODE FLAG
DD	DEC	0		#	DEDA DATA
CMF	DEC	0		#	CLEAR MODE FLAG
A11T	DEC	1.B1		#	TM DIR COSINES
A12T	DEC	0
A13T	DEC	0
ADST	DEC	0		#	DEDA ADDRESS
A31T	DEC	0
A32T	DEC	0
A33T	DEC	1.B1
H	DEC	0B23		#	ALTITUDE
RX	DEC	0B23		#	LM POSITION
RY	DEC	0
RZ	DEC	0
QL	DEC	0B23		#	PRESENT LM PERICYNTHION
EONS10	EQU	QL		#	ENG ON+S10 FOR TM
RCX	DEC	0B23		#	CSM PRESENT POSITION
RCY	DEC	0
RCZ	DEC	0
RF	DEC	0B23		#	PREDICTED BURNOUT ALT.
DVX	DEC	0B1		#	BODY DELTA VS
DVY	DEC	0		#	THIS CYCLE.
DVZ	DEC	0
TA2	DEC	0B1		#	ABS TIME LS.
DAX	DEC	0B-6		#	DELTA ALPHAS
DAY	DEC	0

# Page 9
DAZ	DEC	0
TBO	DEC	0B9		# 	TIME TO BURNOUT.
VX	DEC	0B13		#	LM VELOCITY
VY	DEC 	0
VZ	DEC 	0
MU8S12	DEC	0		#	MU8/S12
VCX	DEC	0B13		#	CSM PRESENT VELOCITY
VCY	DEC	0
VCZ	DEC	0
HDOT	DEC	0B13		#	ALTITUDE RATE
VG	DEC	0B13		#	VELOCITY TO GAIN
VF	DEC	0B13		#	TRANSFER BRAKING VELOCITY
TA0	DEC	0B18		#	TIME FROM CSI TO CDH
TIG	DEC	0B18		#	ABSOLUTE TIME OF MANEUVER
A11BD	DEC	0B1		#	CMD XB POINTING DIR
A12BD	DEC	0
A13BD	DEC	0
TA1	DEC	0B18		#	ABS TIME MS.
S0	DEC	0		#	AGS FUNCTION SELECTOR
DISC1C	DEC	0		#	DISCRETE WD 1-TRUE STATE
Q1DEDA	DEC	8388500B23	#	TRANS ORBIT PERICYN ALT
DELH	EQU	Q1DEDA		#	DIFF. ALT. AFTER CDH(CSI-CDH)
QLTELE	DEC	0B23		#	QL FOR TELE AND DEDA
VD1X	DEC	0B13		#	40MS VEL ACCUMULATION
VD1Y	DEC	0
VD1Z	DEC	0
#		END OF TELEMETRY LIST
DEL6	DEC	0		#	CALIBRATE I.C. FLAG
S10	DEC	0		#	GUIDANCE MODE SELECTOR
S11	DEC	0		#	AUTO RADAR SWITCH
S12	DEC	0		#	TEST STATUS
S13	DEC	0		#	STORE LUNAR AZIMUTH
S14	DEC	0		#	NAVIGATION INITIALIZE
S15	DEC	0		# 	RADAR GIMBAL NULL
RDOTS	EQU	S15		#	R. R. STORED AT RADAR INPUT
S16	DEC	0		#	CDH APSIDAL SELECTION
S17	DEC	0		#	RADAR FILTER INIT. SWITCH

# Page 10
VEX	DEC	0B13		#	CSM EPOCH VEL
VEY	DEC	0
VEZ	DEC	0
RFDOT	DEC	0B13		#	DESIRED ALT RATE
V0X	DEC	0B13		#	PRED EPOCH VEL VECTOR
V0Y	DEC	0
V0Z	DEC	0
I	EQU	V0X		# 	MXM INDEX
J	EQU	V0Y		#	MXM INDEX
K	EQU	V0Z		#	MXM INDEX
VH	DEC	0B13		#	LM HORIZONTAL VEL
#		VIX,VIY,VIZ ARE SHARED WITH RR FILTER
VIX	DEC	0B13		#	ELLIPSE PRED VEL OUTPUT
VIY	DEC	0
VIZ	DEC	0
V	DEC	0B13		#	LM TOTAL VELOCITY
TP	DEC	0B13		#	TRIAL XFR ORB. TIME.
T	DEC	0B13		#	TIME TO RENDEZ.
RB	EQU	T		#	RF SAVED FOR ORBIT INSERT.
TB	DEC	0B13		#	TA-TE.
PDOTM1	DEC	0B13		#	DISPLAY POS RATE(-1)
RRDOT	DEC	0B13		#	RANGE RATE
1000D	DEC	1000B17		#	RANGE MARK COUNTER INCREMENT
TI	DEC	0B13		#	PREDICTION TIME/RR FILTER TEMP
DPDOUT	DEC	0B13		#	DISPLAY POS RATE INCREMENT
PDOUT	DEC	0B13		#	DSP POS RATE CONV TO FPS AT 13
TCSM	DEC	0B13		#	CSM PERIOD (SEC)
4K25	DEC	3.402B13	#	ENG CUTOFF COMP
2K18	DEC	15.B13		#	PARTIAL DERIV PROTECTOR.
28J1	DEC	0B13		#	DELTA V DOWNRANGE
28J2	DEC	0B13		#	DELTA V CROSSRANGE
28J3	DEC	0B13		#	DELTA V RADIAL
2K20	DEC	2.B13		#	CONVERGENCE CHECK.
4K26	DEC	70.0B13		#	VG THRESHOLD
DDF	DEC	0		#	DEDA DATA RECEIVED FLAG
6K4	DEC	.1E3B10		#	INITIAL VALUE OF P33 AND P44
6K2	DEC	.1E9B30		#	INIT VALUE OF P11,P22

# Page 11
V5X	DEC	0B13		#	TPI-PREDICTED V AT TPI TIME
V5Y	DEC	0
V5Z	DEC	0
TR4	EQU	V5X		#	NO. OF COL IN MATRIX A
TR6	EQU	V5Y		#	NO. OF ROWS IN MATRIX B
TR5	EQU	V5Z		#	NO. OF ROWS IN MATRIX A
VHA	DEC	0B13
22J	DEC	50B13		#	PITCH STEERING ALT RATE THRESH
23J	DEC	19.5B13		#	RFDOT LOWER LIMIT
5K26	DEC	15B13		#	PSEUDO ATT HOLD IN STEER
PART	DEC	0B14		#	PARTIAL DERIVATIVE
VDX	DEC	0B13		#	VD1 AT NAV UPDATE
VDY	DEC	0
VDZ	DEC	0
4K27	DEC	-8000.0B13	#	OVERFLOW PROTECTION FOR VD1X
VSMGX	DEC	0B13		#	VD1 CUTOFF
VSMGY	DEC	0
VSMGZ	DEC	0
RADOT	DEC	0B13		#	PRED. RDOT AT TIG
DELVGX	DEC	0B13		#	THRUST VEL TO GAIN
DELVGY	DEC	0
DELVGZ	DEC	0
17J	DEC	0B13		#	RANGE RATE INPUT
RD3DOT	DEC	0B-2		#	DESIRED RADIAL JERK
YD3DOT	DEC	0B-2		#	DESIRED OUT-OF-PLANE JERK
4K12	DEC	5B7		#	ACCEL THRESH IN O.I. STEER
S507	DEC	0B3		#	ACQ STEER SEL OF PT DIR
DAXREM	DEC	0B-13		#	INCRE. GYRO INPUT REMAINDERS
DAYREM	DEC	0
DAZREM 	DEC	0
C1 	DEC	0B1		#	RENDEZ ANGLE COSINE.
WBX	DEC	0B1		#	UNIT VECTOR FOR
WBY	DEC	0		#	GUIDANCE STEERING
WBZ	DEC	0
6K14	DEC	-15768B14	#	RADAR RANGE RATE NULL
TE1	DEC	0B18		#	CSM EPOCH TIME MS.
TL1	DEC	0B18		#	LEM EPOCH TIME MS.


# Page 12
6K6	DEC	-.001B-8	#	Y-VELOCITY FILTER WEIGHT
5K20	DEC	0B-2		#	RD3DOT LOWER LIMIT
TE2	DEC	0		#	CSM EPOCH TIME LS.
TL2	DEC	0		#	LEM EPOCH TIME LS.
2K11	DEC	6000B13		#	VF IF OVERFLOW
4K6	DEC	80.B13		#	RFDOT UPPER LIMIT
DAXA	DEC	0B-6		#	ALIGN INCREMENTS
DAYA	DEC	0
DAZA	DEC	0
DISC1	DEC	0		#	DISCRETE WORD
1K18	DEC	.003125B-8	#	ACCEL SCALE FACTOR
1K20	DEC	.003125B-8
1K22	DEC	.003125B-8
1K14	DEC	0B-14		#	X-AXIS MASS UNBAL COMP
1K19	DEC	0B1		#	ACCEL BIAS
1K21	DEC	0B1		#	COMPENSATION
1K23	DEC	0B1
DSPSC	DEC	0		#	DISPLAY SHIFT COUNTER
1K1	DEC	0B-13		#	GYRO BIAS
1K6	DEC	0		#	COMPENSATIONS
1K11	DEC	0
DDEL	DEC	0B0		#	LUNAR ALIGN CORRECTION
1K3	DEC	0B-7		#	GYRO SCALE FACTOR
1K8	DEC	0		#	COMPENSATIONS
1K13	DEC	0
HRF	DEC	0		#	HIGH RATE FLAG
A31S	DEC	0B1		#	RADAR NULL DIR COS
A32S	DEC	0
A33S	DEC	0
4K4	DEC	.004B-7		#	FACTOR IN RFDOT(OI)
5K14	DEC	0B-2		#	RD3DOT UPPER LIMIT
5K16	DEC	.01B-2		#	YD3DOT UPPER LIMIT
DLWN	DEC	0		#	DOWNLINK WORD COUNTER
DEL32	DEC	0		#	DOWNLINK INITIALIZE FLAG
6K8	DEC	.22B10		#	RANGE RATE ERROR VARIANCE
#					(ADDR OF 6K8 MUST END IN 4)
6K9	DEC	.3029E-4B-4	#	VARIANCE OF RADAR ANGULAR ERROR

# Page 13
6K10	DEC	.625E7B28	#	RANGE ERROR VARIANCE
DSPF1	DEC	0		#	DISPLAY FLAG1.
ID1F	DEC	0		#	DOWNLINK ID RECEIVED
DEL31	DEC	0		#	DOWNLINK INPUT COMPLETE
FLAGT	DEC	0		#	MEMORY TEST
FLAG1	DEC	0		#	20MS BRANCH CONTROL
DEL2	OCT	0		#	STAGED FLAG.
DEL5	OCT	0		#	ATTHLD LOCK FLAG.
PI	DEC	3.14159266B3
6K13	DEC	-1.59286B1	#	RADAR RANGE RATE TO FPS AT 13
DVGXX	DEC	0B13		#	VEL TO GAIN IN EXT DELTA V
DVGXY	DEC	0
DVGXZ	DEC	0
DEL20	DEC	0		#	LOGIC FLAG FOR ENG CONTROL
DEL21	OCT	0		#	LUNAR SURFACE FLAG.
2J	DEC	1.9970B7	#	COTAN OF DESIRED LOS AT TPI
DEL42	OCT	0		#	LUNAR ALINE COMPLETE FLAG
DEL45	EQU	DEL42		#	RR RANGE/RANGE RT. UPDATE FLAG
K55	OCT	377777		#	S.F. FOR HDOT DISPLAY
MU3	DEC	0		#	P-ITER COUNTER.
RD3DTL	EQU	MU3		#	RD3DOT LOWER LIMIT
5K17	DEC	-.01B-2		#	YD3DOT LOWER LIMIT
MU6	DEC	0		#	STAGING COUNTER
1K37	DEC	15.B17		#	ACCEL CAL DURATION
MU8	DEC	0		#	ULLAGE COUNTER
MU10	DEC	0		#	GYRO CALIBRATE DURATION
1K9	DEC	5.0B17		#	ULLAGE COUNTER LIMIT
1K30	DEC	150.B17		#	GYRO CALIBRATE DURATION
2K17	DEC	5.B17		#	NO OF P-ITERATIONS-3
MU19	DEC	0		#	MARK COUNTER
4K23	DEC	62.0B17		#	STAGING TIME DELAY
S623	DEC	0B3		#	EX SELECTION IN G. S
1K4	DEC	.1B0		#	DISPLAY INTERPOLATION
1K24	DEC	.87E-3B1	#	SINGULARITY THRESHOLD
1K26	DEC	-.142857E3B8	#	NEG INV OF ALIGN GAIN CONSTANT
1K27	DEC	.435E-1B-4	#	ALIGN CONSTANT
1K28	DEC	107.78396B7	#	ALIGN CONSTANT

# Page 14
1K29	DEC	.001B-4		#	LUN ALIGN STOP CRITERION
1K33	DEC	.08B-3		#	CALIBRATE GAIN
1K34	DEC	.00002B-15	#	CALIBRATE GAIN
1K35	DEC	.25B7		#	ACCEL BIAS THRESHOLD
1K36	DEC	-.66667E-3B0	#	ACCEL CAL GAIN
2K1	DEC	.173189E15B48	#	GRAVITY CONST (LUNAR)
2K2	DEC	.57740387E-14B-47 #	1/2K1
6J1	DEC	.3358E-8B-14	#	LUNAR ROT RATE ABOUT X-REF
6J2	DEC	-.53039E-7B-14	#	LUNAR ROT RATE ABOUT Y-REF
6J3	DEC	.3052E-8B-14	#	LUNAR ROT RATE ABOUT Z-REF
B13SF	DEC	.10416666B0	#	.01 MIN TO SEC AT 13
SDVX	DEC	0B1		#	DV SUM FOR ACCEL CAL
SDVY	DEC	0		#	(ADDR OF SDVX MUST END IN 4)
SDVZ	DEC	0
MU7	DEC	0B17		#	CALIBRATION COUNTER
7K2	DEC	2B17		#	NOISEIN P-MATRIX DIAGONALS
B13VSF	DEC	.625B0		#	.1 FPS TO FPS AT 13
B3SF	DEC	.34971155B0	#	.01 DEG TO RAD AT 3
B23RSF	DEC	.10533045B0	#	.1 NMI TO FT AT 23
4K2	DEC	-.50204E-4B-12	#	FACTOR IN TB COMP
4K3	DEC	.16803E-8B-25	#	FACTOR IN TB COMP
B22RSF	DEC	.5266522B0	#	.01 NMI TO FT AT 22
BACCSF	DEC	0.762939B0	#	.001 FT/SEC2 TO FPS/20MS AT 1
4K34	DEC	1.B7		#	AT LOWER LIMIT
4K35	DEC	.1B7		#	ULLAGE THRESHOLD
4K10	DEC	-317438.91B20	#	TERM IN AL(O.I.)
SUMLIM	DEC	0		#	LAST CELL FOR CHECKSUM
WORDS	DEC	28
B18SF	DEC	.333333B0	#	.1 MIN TO SEC AT 18
4K21	DEC	.26179938B2	#	SC FACTOR FOR ATT ERR OUTPUT
M25B16	DEC	-25.B16		#	CYCLE COUNT TO SECONDS
DTB	DEC	1.25B1		#	1 SEC + DEDA TIME BIAS
ID	DEC	0		# 	CURRENT DOWNLIST ID CODE
DLWNL	STO	1J1+15		#	END OF DOWNLINK BUFFER
11J	DEC	-624599.84B20	#	RETARGET VALUE FOR 4K10
2K4	DEC	-.173189E15B48	#	(-2.)(2K1) B49
KDT	DEC	1.B1		#	DELTA T/2 AT 1

# Page 15
BM13SF	DEC	.96049535B0	#	.01 DEG/HR TO RAD/20MS AT -13
B23SF	DEC	.64B0		#	100 FT TO FT AT 23
#		THE FOLLOWING 16 PARAMETERS HAVE
#		VARIABLE SCALING.  INITIAL SCALING IS INDICATED.
P11	DEC	.1E9B30		#	VARIANCE OF X-POS ERROR
P12	DEC	0B30		# 	COVARIANCE OF X AND Y POS ERROR
P13	DEC	0B20		#	COVAR OF X-POS AND X-VEL ERROR
P14	DEC	0B20		#	COVAR OF X-POS AND Z-VEL ERROR
P21	DEC	0B30		#	COVAR OF X AND Z POS ERROR
P22	DEC	.1E9B30		#	VARIANCE OF Z-POS ERROR
P23	DEC	0B20		#	COVAR OF Z-POS AND X-VEL ERROR
P24	DEC	0B20		#	COVAR OF Z-POS AND Z-VEL ERROR
P31	DEC	0B20		#	COVAR OF X-POS AND X-VEL ERROR
P32	DEC	0B20		#	COVAR OF Z-POS AND X-VEL ERROR
P33	DEC	.1E3B10		#	VARIANCE OF X-VEL ERROR
P34	DEC	0B10		#	COVAR OF X-VEL AND Z-VEL ERROR
P41	DEC	0B20		#	COVAR OF X-POS AND Z-VEL ERROR
P42	DEC	0B20		#	COVAR OF Z-POS AND Z-VEL ERROR
P43	DEC	0B10		#	COVAR OF X-VEL AND Z-VEL ERROR
P44	DEC	.1E3B10		#	VARIANCE OF Z-VEL ERROR
VRSH	STQ	SREX2
	LRS	0
	TRA	SREX2
TMID	DEC	0		#	TELEMETRY ID
SFLO	OCT	000026
PMAXP	OCT	377777		#	COUNTS AT 17
ORBRET	TRA	DX10P		#	RETURN FROM NORTON IN O.I.
DEDASC	DEC	0		#	DEDA SHIFT COUNTER
#
#
EX36P	STQ	DEL10
#		SAVE QUANTITIES FOR LATER USE IN
#		T/B COMPUTATIONS
	STO	V6Z
	CLA	TS12
	STO	V6X
	CLA	TS13
	
# Page 16
	STO	V6Y
	CLA	TI
	SUB	4J
	TRA	DXFR14-2
RREX	CLA	TS0		# VARIABLE ADDRESS LOAD, MULTIPLY
RREX1	MPY	TS0		# AND STORE FOR MATRIX MULTIPLY
	DVP	1B3		# ROUTINE (MXM) -- PERFORMS
	ADZ	TR8		# C(I,J)=C(I,J)+A(K,I)*B(J,K)
RREX2	STO	TS0
	STO	TR8		# C(I,J)=C(I,J)+A(K,I)*B(J,K)
	CLA	RREX
	ADD	TR4		# INCREMENT CLA
	STO	RREX
	CLA	RREX1
	ADD	1B17		# INCREMENTY MPY
	STO	RREX1
	AXT	2,1		# INCREMENT AND TEST INDEXES
	CLA	I,1
	ADD	1B17
	STO	I,1
	SUB	TR4,1
	TMI	R1+1
	TIX	*-5,1
	CLA	TR6		# REARRANGE DIMENSIONS AND
	STO	TR4		# ADDRESSES ON EXIT TO SAVE
	CLA	TR3		# STEPS IN FILTER
	STO	TR1
	AXT	7,1
	TRA	PP		# EXIT MXM
DIAK1	OCT	377363		# TEST FOR DEDA ENTRY INTO 415
DIAK2	OCT	377401		# TEST FOR DEDA ENTRY INTO 377
6K8S	DEC	.22B10		# WORKING VALUE OF 6K8
#				  (ADDR OF 6K8S MUST END IN 4)
6K9S	DEC	.3029E-4B-4	# WORKING VALUE OF 6K9
6K10S	DEC	.625E7B28	# WORKING VALUE OF 6K10
6K6S	DEC	0		# WORKING VALUE OF 6K6
#

# Page 17
#
	ORG	1000
CLADD	DEC	0		# PICKUP DEDA DATA
	TRA	ROR
RND	STQ	SREX		# DIRECTION COSINE ROUND
	ADD	1B9
	LRS	9
	TRA	SREX
TMCLA	CLA	0324		# CLA FOR TELEM
TCLTH	CLA	1005
DLSTO	STO	1J1-1
IC1BR	TRA	IC1		# IC1 TRA.
BR1	TRA	NAV1P
DEDABR	TRA	DEDAE		# DEDA BRANCH TRA.
BR50	TRA	EXEC2		# BRANCH 50 TRA.
#
#		HARDWIRE ESCAPE POINTS
#
EXIT1	TRA	EX1+1
EXIT2	TRA	UBCOMP
EXIT3	TRA	ADDMS
EXIT4	TRA	EX4+1
EXIT5	TRA	PGNSDE
EXIT6	TRA	TME
EXIT7	TRA	PGNSD1+5
EXIT8	TRA	EX8+1
EXIT9	TRA	TVTG
EXIT10	TSQ	SOFT1
EXIT11	TSQ	SOFT1		# ASCENT ENG ON
EXIT12	TRA	AHE1
EXIT13	TRA	EROUT+1
EXIT14	TSQ	SOFT2
EXIT15	TRA	LUNAL1		# GAIN CHANGE
EXIT16	TRA	EX16+1
EXIT17	TRA	FDAI1
EXIT18	TRA	NOC
EXIT19	TRA	DELAY


# Page 18
EXIT20	TRA	DLDC
EXIT21	TRA	TIMEA
EXIT22	TRA	IDLE-1
O25C	OCT	377747		# TEST FOR TM RESET
EXIT23	CLZ	VD1X
	CLZ	VD1Y
	CLZ	VD1Z
	TRA	NAV3
EXIT24	TRA	NAV2
EXIT25	TRA	NAV3
SINITC	CLA	4K27
	STO	VD1X
	STO	VDX
	TRA	EXEC1+7
EXIT26	TRA	XDVS
EXIT27	TRA	EX27+1
EXIT28	TRA	EX28+1
STGCTR	CLZ	MU6		# STAGING DELAY COUNTER
	ADD	1B17
	STO	MU6
	TRA	AHE
EXIT29	TRA	EX29+1
CLATAB	CLA	SFTAB-1		# CLA FOR DEDA SF TABLE
EXIT30	TRA	EX30+1
EXIT31	TRA	ALTUP
EXIT32	TRA	LMORB2
EXIT33	TRA	EX33P
EXIT34	TRA	EX34P
EXIT35	TRA	EX35
EXIT36	TSQ	EX36P
EXIT37	TRA	EX35+1
EXIT38	TRA	Q5
EXIT39	TRA	EXECM
EXIT40	CLZ	S0		# SOFT INITIALIZE
	CLZ	DEL5
	CLZ	FLAGT
	AXT	7,1		# ZERO S SWITCHES

# Page 19
	CLZ	S10,1
	TIX	*-1,1
	TRA	SINITC		# CONTINUE INITIALIZE
EXIT41	TRA	DSP1
EXIT42	TRA	DSP2CP
EXIT43	ADD	O25C		# CHECK FOR TM RESET
	ABS
	TMI	TMIE1		# -- RESET TM AT 25 CYCLE
	TRA	EXEC1+4		# NOT 25TH CYCLE
IDAI	OCT	077776		# AGS INITIALIZE DOWNLIST ID
IDRP	OCT	077775		# REND./PRETHRUST DOWNLIST ID
EXIT44	TRA	EX44+1
EXIT45	TRA	EX45+1
EXIT46	TRA	EX46+1
EXIT47	TRA	DEXIT
EXIT48	TRA	CLEARM+1
EXIT49	TRA	SFTEST
EXIT50	TRA	EX50+1
EXIT51	TSQ	DIAT
EXIT52	TRA	EXEC+1
EXIT53	TRA	EXEC+1
DLWNLC	STO	1J1+15		# DLWNL PROTECTION
ADDMS	AXT	2,1
	CLA	TS10,1
	ABS
	ADD	MS
	TIX	*-3,1
	TRA	EX3+1
EX34P	CLZ	DEL10
	TMI	EX33PP+1
	TRA	EX34+1
THEF	CLA	RF
	LRS	1		# B24
	ADZ	TS3
	LDQ	TS4
	STO	TS4		# =RF+RX B24
	STQ	TS3		# =RZ B24
	
# Page 20
	TSQ	ARCTAE
	STO	TS0		# THETAF B8
	SUB	PI
	TMI	*+2
	SUB	2PIB3
	ADD	PI
	STO	THETAF		# THETAF B3
	CLA	TS0		# B3
	SUB	2PIB3
	MPY	M1B1		# B4
	DVP	NI
	ADD	TI		# B13
	TRA	DXFR14-2
TMIE1	TSQ	TMIE2		# INITIALIZE TELEMETRY
	CLA	S12
	ADD	MU8
	STO	MU8S12		# SAVE MU8/S12 FOR TM
	SUB	3B3		# TEST FOR SELF TEST FAILURE
	TMI	*+2
	OUT	6410		# SET FAILURE INDICATOR
	TRA	DELAY		# END MAJOR CYCLE
#
# 	DEDA SCALE FACTOR LOCATOR TABLE
#	SCALE FACTORS MUST REMAIN AT LOCS IN COMMENTS
#	FORMAT OF TABLE IS, BIT 0=1 TABLE EXCEEDED,
#	BITS 1-9 LAST ADDRESS OF DEDA SCALE FACTOR REGION
#	BIT 10=1 FOR OCTAL REGION, BITS 11-17 ADDRESS OF
#	SCALE FACTOR RELATIVE TO LOCATION 636
SFTAB	OCT	075200		# OCT LOC 026-172,OCT
	OCT	125441		# OCT LOC 173-253,DEC,SF AT 677
	OCT	127427		# OCT LOC 254-257,DEC,SF AT 665
	OCT	134413		# OCT LOC 260-271,DEC,SF AT 651
	OCT	137027		# OCT LOC 272-276,DEC,SF AT 665
	OCT	142414		# OCT LOC 277-305,DEC,SF AT 652
	OCT	145405		# OCT LOC 306-313,DEC,SF AT 643
	OCT	146415		# OCT LOC 314-315,DEC,SF AT 653
	OCT	147420		# OCT LOC 316-317,DEC,SF AT 656
	
# Page 21
	OCT	157415		# OCT LOC 320-337,DEC,SF AT 653
	OCT	164441		# OCT LOC 340-351,DEC,SF AT 677
	OCT	174413		# OCT LOC 352-371,DEC,SF AT 651
	OCT	177427		# OCT LOC 372-377,DEC,SF AT 665
	OCT	200600		# OCT LOC 400-401,OCT
	OCT	202415		# OCT LOC 402-405,DEC,SF AT 653
	OCT	207600		# OCT LOC 406-417,OCT
	OCT	241413		# OCT LOC 420-503,DEC,SF AT 651
	OCT	257600		# OCT LOC 504-537,OCT
	OCT	261421		# OCT LOC 540-543,DEC,SF AT 657
	OCT	263040		# OCT LOC 544-546,DEC,SF AT 676
	OCT	305600		# OCT LOC 547-613,OCT
	OCT	311067		# OCT LOC 614-622,DEC,SF AT 725
	OCT	342200		# OCT LOC 623-704,OCT
#	THE ABOVE 23-PLACE TABLE MUST BE FOLLOWED 
#	BY A WORD WITH BIT 0 SET
#
#	ORBIT ALIGN COMPUTATIONS
#
ORBLIN	AXT	6,1
	CLZ	A11,1
	CLZ	DA11,1		# ZERO REMAINDERS
	TIX	*-2,1
	CLA	1B1
	STO	A11
	STO	A33
	TRA	COA21-2
#
#	MASS UNBALANCE COMPENSATION
#
UBCOMP	MPR	1K14		# (DVX)(1K14)	1+(-14)=-13
	ADZ	DAXREM
	STO	DAXREM
#
#		20MS MODE CHECK.
#
MODCK	CLA	S0		# CHECK FOR ALIGNMENT

# Page 22
	SUB	3B3		# SUBMODES
	TMI	GYCOM-2		# -- IS INERT REF
	SUB	1B3
	TMI	ZNOC		# IMU ALIGN
	SUB	1B3
	TMI	GYCOM-2		# -- IS LUNAR ALIGN
	SUB	1B3
	TMI	ORBLIN		# ORBIT ALIGN
	AXT	2,1		# CALIBRATE MODE
CALIB1	CLA	DEL21
	TMI	*+5		# -- LM IS ON LUNAR SURFACE
	CLZ	SDVX,1		# SUM BODY AXIS VEL
	ADD	DVX,1		# INCREMENTS SINCE START OF ACC.
	STO	SDVX,1		# BIAS CALCULATIONS
	TRA	CALIB2
	CLA	A11,1		# LUNAR CAL., COMPENSATE COMP.
	MPR	6J1,1		# OF VEH ROT. FOR LUNAR ROTATION
	ADZ	DAXREM		# 1+(-14)=-13
	STO	DAXREM		# A11 DOT 6J1
	CLA	A21,1
	MPR	6J1,1
	ADZ	DAYREM
	STO	DAYREM		# A21 DOT 6J1
	CLA	A31,1
	MPR	6J1,1
	ADZ	DAZREM
	STO	DAZREM		# A31 DOT 6J1
CALIB2	TIX	CALIB1,1
	TRA	GYCOM-2
#
#		DEDA MODE SELECTION
#
DEDAE	CLZ	CLEARP
	TMI	CLEARM		# SET CLEAR
	CLA	CMF
	TMI	RPT		# CLEAR MODE
	CLA	RMF
	
# Page 23
	TMI	HET		# READOUT IN PROGRESS
	CLA	HMF
	TMI	RRT		# HOLD IN PROGRESS
DEXIT	AXT	3,1		# NORMAL EXIT
	TRA	*+4
CLEARM	STO	CMF
	INP	DEDA
	AXT	5,1		# CLEAR EXIT
	CLZ	READP,1		# RESET FLAGS
	TIX	*-1,1
	CLZ	TMPBR		# SET BRANCH FOR NEXT
	STO 	BRANCH		# GUIDANCE CYCLE
	CLA	1B11		# INITIALIZE COUNTER
	STO	DEDASC
	TRA	DSP1		# TO DISPLAY
RPT	CLZ	READP		# TEST FOR
	TMI	RME		# READOUT MODE
	CLZ	ENTERP		# OR ENTER MODE
	TMI	RME+1		# ENTRY.
	TRA	DEXIT		# EXIT
HET	CLZ	HOLDP		# READOUT TEST FOR
	TMI	*+2		# HOLD COMMANDED
	TRA	ADOUT		# TO OUTPUT ROUTINE
	STO	HMF		# SET HOLD MODE
	CLZ	RMF
	TRA	DEXIT
#
# 	DEDA SCALE FACTOR SELECTION
#
SFTEST	SUB	SFLO
	TMI	CLEARM+1	# -- IF OCT LOC BELOW 0026
	CLA	CLATAB		# INITIALIZE FIRST TABLE VALUE
	STO	VRSH+1		# STORE CLA INSTRUCTION
	CLA	VRSH+1		# INCREMENT CLA INSTRUCTION
	ADD	1B17		# ADDRESS
	STO	VRSH+1
	TSQ	VRSH
	
# Page 24
	TMI	CLEARM+1	# -- IF OCT LOC ABOVE 704
	LRS	8		# EXAMINE BITS 1-9 OF VALUE
	SUB	ADST		# -- IF OCT LOC ABOVE VALUE,
	TMI	*-7		# CHECK NEXT VALUE IN TABLE
	LLS	18		# RECOVER BITS 10-17 OF THIS VAL
	TMI	NOTDD		# -- IF OCT REGION, NO SF REQ
	LRS	10		# SCALE BITS 11-17 OF VAL
	ADD	TBRAKE		# CONSTRUCT INSTRUCTION TO OBTAIN
	STO	VRSH+1		# SCALE FACTOR FOR THIS REGION
	TSQ	VRSH		# OBTAIN SF FOR THIS REGION
	STO	SF		# SET SCALE FACTOR
	TRA	DDIN		# TO INPUT ROUTINE
DIAT	AXT	1,1		# IMMEDIATE ACTION TEST
	CLA	ADST		# IMMED. ACTION IF
	ADD	DIAK1,1		# ACCUMULATOR = 400000
	ABS
	TMI	*+4
	TIX	DIAT+1,1
	STQ	DDF
	TRA	DEXIT
	TIX	ATI,1
	LDQ	*-2		# SET RETURN TO DEXIT
	AXT	2,1
	CLA	RRX,1		# SAVE RANGE FOR FILTER
	STO	RRSX,1
	CLA	A31,1		# STORE DIRECTION COSINES
	STO	A31S,1
	TIX	*-4,1
	CLA	RRDOT
	STO	RDOTS
	TRA	EXIT
#
#		DOWNLINK FORMATTING
#
DLDC	AXT	2,1
	CLZ	0244,1		# LEM VEL
	STO	1J4,1
	
# Page 25
	CLZ	0250,1		# CSM POS
	STO	2J1,1
	CLZ	0254,1		# CSM VEL
	STO	2J4,1
	TIX	DLDC+1,1
	CLZ	0247
	LRS	14
	ADZ	0243
	STO	1J7
	STQ	1J7LS
	STO	2J7
	STQ	2J7LS
	TSQ	CSMPV
	TRA	IC1+3
#
#		DELTA V ACCUMULATION AND THRUST VEL TO GAIN.
#
TVTG	AXT	2,1
	CLA	DVX,1		# 1
	LRS	1		# TO 2
	ADZ	VD2X,1
	STO	VD2X,1
	CLA	DVXM1,1
	LRS	1		# TO 2
	ADZ	VD2X,1
	STO	VD2X,1
	LRS	11		# TO 13
	STO	TS1
	ALS	11
	COM
	ADZ	VD2X,1
	STO	VD2X,1		# REMAINDER AT 2
	CLA	VD1X,1		# DV EXPENDED MS.
	ADZ	TS1
	STO	VD1X,1		# VD1 AT 13
	COM
	ADD	VSMGX,1		# VSMG-VD1
	
# Page 26
	STO	DELVGX,1	# THRUST VEL TO GAIN
	CLZ	EX,1
	TIX	TVTG+1,1
	TRA	EX9+1
#
#	SOFT 40MS COMPUTATIONS
#
SOFT1	CLA	S0		# TEST MODE
	SUB	3B3
	STO	TS1		# SAVE
	TMI	IR		# -- IS INTERT. REF.
ZERR	CLA	ZERO
	OUT	6007		# ZERO ATTITUDE ERRORS
	CLZ	DEL5		# RESET ATT HOLD INIT FLAG
	CLZ	TS1
	TMI	ENCOM1		# -- IS INERTIAL REF
	SUB	1B3
	TMI	SOFT3
	SUB	1B3
	TMI	LUNAL
SOFT3	OUT	7040		# RESET ENG ON
	OUT	6420		# SET ENG OFF
	CLA	ZERO		# SET ENG TM FLAG PLUS
	ADD	S10
	STO	EONS10	
	TRA	FDAI		# TO ATTITUDE DISPLAY
ENCOM1	CLA	DISC1		# FOLLUP ENG. COMMANDS
	LLS	5
	TMI	*+4		# -- DESCENT ENG ON
	LLS	1
	TMI	*+2		# -- ASCENT ENG ON
	TRA	SOFT3		# ENG OFF
	OUT	7020		# RESET ENG OFF
	OUT	6440		# SET ENG ON
	CLA	MS		# SET ENG TM FLAG NG
	TRA	SOFT3+3
IR	CLA	S11		# TEST FOR AUTO RADAR DATA


# Page 27
	ALS	3
	TMI	RADCK
	STO	DEL44		# SET/RESET CODE WORD FLAG
IR4	CLA	DISC1
	ALS	3
	TMI	IR1		# -- IS FOLLOWUP
	ALS	1
	TMI	IR2		# -- IS AUTOMATIC
	STQ	DEL20
	TRA	AHE		# TO ATT HOLD
IR1	CLA	DISC1C
	ALS	4
	TMI	ZERR		# PLUS IS AUTOMATIC
	CLZ	DEL5
	STQ	DEL20
	TRA	MODE
RSTE	CLA	S623
	ALS	3
	TMI	*+3
	CLA	WCX,1
	TRA	*+2
	CLA	WBX,1
	MPR	A31,1
	COM
	ADZ	EX
	STO	EX
	TIX	RSTE,1
RST1	TRA	RST
IR2	ALS	4
	TMI	IR3		# -- IS ABORT STAGE
	CLA	DEL21		# IF ON LUNAR SURFACE
	TMI	ZERR		# OUTPUT ZERO ATT ERRORS
	CLA	DISC1
	ALS	7
	TMI	MODE		# -- IS ABORT
	TSQ	IR1+4
IR3	CLA	DEL21

# Page 28
	TMI	AHE
	CLA	DISC1C
	ALS	6
	TMI	MODE
	CLA	MU6
	SUB	4K23
	TMI	STGCTR		# STAGING ATT HOLD
MODE	CLA	S0		# TEST STEERING MODE
	SUB	1B3
	TMI	AHE		# ATT HOLD
	AXT	2,1
	SUB	1B3
	TMI	RSTE		# RENDEZVOUS STEERING
	CLZ	DEL5		# ACQUISITION STEERING
MODE1	CLA	WCX,1
	MPR	A11,1
	ADZ	EZ
	STO	EZ
	CLA	S507		# ORIENT LM Z-BODY ASIX
	SUB	1B3		# IN DESIRED THRUST DIR.
	TMI	*+3		# OR ESTIMATED CSM DIR.
	CLA	A11BD,1
	STO	A31BD,1
	CLA	A31BD,1
	MPR	A11,1		# XB
	ADZ	EY
	STO	EY
	CLA	A31BD,1		# ZBD
	MPR	A21,1		# YB
	COM
	ADZ	EX
	STO	EX
	TIX	MODE1,1
	TRA	EROUT
SOFT2	CLZ	DEL20		# FIRST TIME FOLLOW
	TMI	ENCOM1		# PREVIOUS ENGINE STATE
	CLA	S0		# IF NOT GUIDANCE STEERING
	
# Page 29
	ALS	3		# TURN ENGINE OFF
	TMI	*+2
	TRA	SOFT3
	CLA	MU8		# TEST FOR ULLAGE
	SUB	1K9
	TMI 	SOFT3
	CLA 	4K25		# TEST CEL TO BE
	SUB	DELVGX		# GAINED GREATER THAN
	TMI	ENCOM1+6	# SHUTDOWN THRESHOLD
	CLA	4K26
	SUB	VG
	TMI	ENCOM1+6
	CLZ	S0		# SET ATT HOLD
	TRA	SOFT3
RADCK	STQ	DEL32		# REINITIALIZE DOWNLINK
	CLA	IDRP		# SET DOWNLIST ID TO REND/PRETHRJ
	STO	ID
	CLA	DEL46		# IS CODE WORD RESET
	ALS	1
	ABS
	TMI	IR+3
	ADD	1B12		# IS CODE WORD SET
	ABS
	TMI	*+2		# YES IF NEGATIVE
	TRA	IR4
	CLZ	DEL44		# HAS CODE WORD BEEN RESET
	TMI	*+2		# PRIOR TO BEING SET
	TRA	IR4		# NO
	TOV	*+1
	AXT	1,1		# IF SHAFT OR TRUNNION
	CLA	THETAR,1	# ANGLE IS GREATER
	ALS	4		# THAN 11.2 DEG, THEN 
	TOV	IR4		# DO NOT PROCESS
	TIX	*-3,1
	CLZ	DEL45		# ALTERNATE RANGE, RATE
	TMI	IR6
	STQ	DEL45
	
# Page 30
	CLZ	RM		# RANGE ENTRY
	LRS	18
	CLZ	DEL46		# TEST FOR HIGH SCALING
	TMI	*+2
	LRS	3		# LOW SCALE
	LLS	17
	MPR	6K12		# COUNTS TO FEET AT 22
	STO	18J
	TRA	*+5
IR6	CLZ	RMDOT		# RANGE RATE ENTRY
	SUB	6K14		# NULL AT 17000
	DVP	6K13		# COUNTS TO FT/SEC AT B13
	STO	17J
	TSQ	DIAT+10		# SAVE REL RNG VECT, REL VEL
	AXT	2,1
IR5	CLA	A21,1		# B1, ADJUST Z BODY FOR SHAFT
	MPR	THETAR		# B1+B0=B1, AND TRUNNION ANGLES
	DVP	6K11		# B1-B0=B1
	STO	A31S,1		# B1
	CLA	A11,1		# B1
	MPR	BETAR		# B1+B0=B1
	DVP	6K11		# B1-B0=B1
	SUZ	A31S,1		# B1
	ADD	A31,1
	STO	TS14,1		# XB*BETAR/6K11-YB*THETAR/6K11+ZB
	TIX	IR5,1
	TSQ	NORMV
	AXT	2,1
	CLZ	TS10,1		# MOVE NORMALIZED DIRECTION
	STO	A31S,1		# INTO ZB*
	TIX	*-2,1
	TRA	4711		# EXIT TO DEDA DISCRETE SAMPLING
LUNAL1	CLZ	DAYA		# CHANGE GAIN
	LRS	2		# 1/4
	STO	DAYA
	CLZ	DAZA
	LRS	2
	
# Page 31
	STO	DAZA
	TRA	SOFT3
#
#		START OF NAVIGATION
#
NAV1P	CLA	DEL21
	TMI	NAV1		# -- IS ON LUNAR SURFACE
	CLA	VD1X		# COMPUTE THRUST ACCEL
	SUB	VDX		# 13
	ALS	5		# 1/2(VD1-VD) AT 7
	TRA	5166		# TO HARD NAV
XDVS	AXT	2,1
	CLA	DVSX,1
	ADD	1B12
	LRS	6
	ADZ	DQSX,1
	STO	DQSX,1
	CLA	VD1X,1
	STO	VDX,1
	TIX	XDVS+1,1
	TRA	NAV4
ALTUP	TSQ	EXEC
#
	AXT	2,1
	CLA	REX,1		# SAVE REX FROM FILTER
	STO	VIX,1		# SCRATCH MATRIX C AREA
	CLA	25J		# ALTITUDE ENTRY TEST
	SUB	1B17
	TMI	FLTR		# IF NO 25J ENTRY
	CLA	25J
	ADD	5J
	STO	R		# R=5J+25J
	MPY	U1X,1
	LLS	1
	STO	RX,1		# NEW R COMPONENTS
#
# 	RANGE AND RANGE RATE COMPUTATIONS

# Page 32
#
FLTR	CLA	RCX,1		# RELATIVE RANGE
	SUB	RX,1
	STO	RRX,1
	STO	TS4,1
	TIX	ALTUP+2,1
	CLZ	25J
	TSQ	DPVMAG		# DP COMP OF RR MAG
	ALS	1
	STO	RR		# B22 RANGE VECTOR MAG
	CLA	2K1		# 48
	LRS	5		# 53
	DVP	R		# 30
	DVP	R		# 7
	DVP	R		# -16
DAD	STO	D11		# 2K1/R**3 B-16
	AXT	7,1
	CLZ	C11,1		# ZERO PHI,M
	CLZ	C31,1
	TIX	*-2,1
	CLZ	RRDOT		# ZEROED FOR SUM
	AXT	2,1
FLTRA	CLA	RRX,1
	DVP	RR
	STO	A31BD,1		# B1 UNIT POINTING VECTOR
	CLA	VCX,1		# B13
	SUB	VX,1
	STO	TS4,1		# B13 RANGE RATE CSM-LM
	MPR	A31BD,1
	ALS	1
	ADZ	RRDOT
	STO	RRDOT
	CLA	U1X,1
	MPR	U1X,1		# B2
	MPR	3B3
	SUB	1B5
	MPR	D11
	
# Page 33
	STO	C31,1		# ADT,JDT AT B-7
	CLA	4B17
	STO	TR4,1		# SET UP DIMENSION FOR MXM
	TIX	FLTRA,1
	LDQ	1B3		# COMMON SETUP OF PHI AND M
	STQ	C11
	STQ	C22
	STQ	C44
	CLA	PAD		# COMMON ADDR SETUP FOR
	STO	TR1		# PHI*P*PHI(T) AND M*P*M(T)
	CLA	CAD
	STO	TR2
	CLA	DEL21		# BYPASS FILTER IF ON SURFACE TO
	TMI	FLTRX		# AVOID CONFLICT WITH D44, SIDELL
#
PUPDAT	CLZ	MU17		# ZERO MU17 IF FILTER TIME
	ADD	1B3
	TMI	FLTRTM
	STO	MU17
FLTRD	CLA	17J
	ABS
	SUB	1B17
	TMI	FLTRH		# NO RATE CHECK RANGE
RATE	CLZ	17J
	SUB	RDOTS
	STO	DELR1		# B13
	AXT	2,1
FLTRE	CLA	RRDOT		# B13
	MPR	A31BD,1		# B14
	DVP	M1B1
	ADD	TS4,1		# B13
	MPY	1B2		# SCALE AT B15
	DVP	RR		# B22
	STO	C11,1		# M11 AT B-7
	CLA	A31BD,1		# B1
	LRS	2
	STO	C12,1		# M14 AT B3
	
# Page 34
	TIX	FLTRE,1
	LDQ	C13
	CLA	C12
	STQ	C12		# M12 AT B-7
	STO	C13		# M13 AT B3
	CLZ	C22		# M22 (M21,M23,M24 ALREADY ZERO)
	CLA	6K8S		# B10
	STO	18J		# N11,(N12=C42=0,N22=C44=1B3)
	CLA	1B17
	TRA	FLTRJ
#
#
FLTRH	ADD	18J		# CHECK RANGE
	TMI	FLTRX
RANGE	AXT	2,1
FLTRI	CLA	A31S,1		# ZB B1
	MPR	18J		# B22
	SUB	RRSX,1
	STO	DELR1,1		# B23
	CLA	RRX,1
	MPR	RRX,1		# B46
	MPY	6K9S		# B42
	LLS	12		# B30
	STO	TS0,1		# B30
	CLA	A31BD,1		# B1
	MPR	A31BD,1		# B2
	MPR	6K10S
	STO	TS4,1
	TIX	FLTRI,1
	ADZ	TS2
	STO	18J		# N11 AT B30
	CLA	RRZ
	MPY	TS0
	DVP	RRX		# B30
	STO	C42		# -N12
	CLZ	TS0
	ADZ	TS6
	
# Page 35
	STO	C44		# N22
#				  M IS ALREADY SET UP IN C11-C24
	CLA	6K5		# B0
	MPR	DELR3		# B 23
	ADD	RY		# Y=Y+6K5*DELR3 B23
	STO	RY
	CLA	6K6S		# B-8
	MPY	DELR3		# B15
	LLS	2		# B13
	ADD	VY
	STO	VY		# VY=VY+6K6*DELR3
	CLA	6K6
	STO	6K6S		# RESTORE GAIN AFTER 1ST PASS
	CLA	1000D
FLTRJ	ADZ	MU19		# INCREMENT MARK COUNTER
	STO	MU19
	CLA	2B17		# DIMENSION FOR MXM (OTHER DIM.
	STO	TR6		# AND ADDR. ALREADY SET UP)
	CLA	DAD
	TSQ	MXM		# RETURN WITH D=P(T)*M(T)
	CLA	C31AD
	TSQ	MXM		# RETURN WITH Q IN C32-C34
	CLZ	C42
	SUB	C32
	STO	C32		# QP12=QP21= -(Q12+N12)
	STO	C33
	MPY	C32
	LLS	3		# (QP12)**2 AT B57(ZERO FOR RATE)
D31AD	STO	D31
	CLA	C31
	ADZ	18J
	LRS	17
	CLA	C34
	ADZ	C44
C31AD	STO	C31		# QP11=Q22+N22
	STQ	C34		# QP22=Q11+N11
	MPY	C34
	
# Page 36
	LLS	3		# QP11*QP22 AT B57(B10 FOR RATE)
	SUB	D31
CAD	STO	C11		# DETERMINANT OF (Q+N) MATRIX
	CLA	DAD
	STO	TR2
	CLA	2B17
	STO	TR5
	CLA	4B17
	STO	TR6
	CLA	D31AD
	TSQ	MXM		# RETURN WITH B(T)*C11 IN D31-D44
	CLA	DELR1		# SETUP FOR TRICKY INDEXING
	STO	C14
	CLA	DELR2
	STO	C24
#		INDEX IS LOADED IN MXM
	CLA	D31,1		# AT B57,B47 (B20,B10 FOR RATE)
	MPY	1B3
	DVP	C11
	STO	D31,1		# B(T) AT B3,B-7(B13,B3 FOR RATE)
	MPY	C14,1		# B(I,1)*DELR1 OR B(I,2)*DELR2
	LLS	3		# TO B23 OR B13
	ADZ	C41,1		# LAST 4 TIMES THRU WILL ADD TO
	STO	C41,1		# VALUES COMPUTED 1ST 4 TIMES
	TIX	*-8,1
	CLA	RX
	SUZ	C41		# B(1,1)*DELR1+B(1,2)*DELR2
	STO	RX
	CLA	RZ
	SUZ	C42		# B(2,1)*DELR1+B(2,2)*DELR2
	STO	RZ
	CLA	VX
	SUZ	C43		# B(3,1)*DELR1+B(3,2)*DELR2
	STO	VX
	CLA	VZ
	SUZ	C44		# B(4,1)*DELR1+B(4,2)*DELR2
	STO	VZ
	
# Page 37
	CLA	CAD
	TSQ	MXM		# RETURN WITH B*M*P IN C11-C44
# 		INDEX IS LOADED IN MXM
	CLA	P11,1		# P=P-B*M*P
	SUZ	C11,1
	STO	P11,1
	CLA	P31,1
	SUZ	C31,1

	STO	P31,1
	TIX	*-6,1
	TRA	FLTRX
FLTRTM	CLA	C33		# FINISH SETUP OF PHI
	STO	C42		# JDT
	STQ	C33		# 1B3
	CLA	U1X
	MPR	U1Z
	MPR 	3B3		# B5
	MPZ	D11
	STO	C32		# CDT AT B-7
	STO	C41
	CLA	1B9		# DT AT B13
	STO	C13
	STO	C24		# NOW HAVE PHI IN C11-C44
	CLA	DAD
	TSQ	MXM		# RETURN WITH D = P(T)*PHI(T)
	CLA	PAD
	TSQ	MXM		# RETURN WITH P=D(T)*PHI(T), OR
#			 	  P(NEW = PHI*P(OLD)*PHI(T)
	CLA	P11		# ADD STATE NOISE TO DIAGONALS
	ADD	7K2
	STO	P11
	CLA	P22
	ADD	7K2
	STO	P22
	CLA	P33
	ADD	7K2
	STO	P33
	
# Page 38
	CLA	P44
	ADD	7K2
	STO	P44
	TSQ	EXEC
	TOV	*+1		# RESET OVERFLOW
	CLA	SICO2+1		# ALS 2
	TSQ	STEST		# TEST FOR SCALING TOO LOW
	CLA	CDCC+2		# LRS 1
	TOV	RSHFT		# NEED RIGHT SHIFT IF OVERFLOW
	CLA	LRI+2		# ALS 3
	TSQ	STEST		# SEE IF SCALING DOWN IS POSSIBLE
	CLA	GYCOM+2		# ALS 1
RSHFT	STO	VRSH+1
	AXT	2,1
	CLA	6K8S,1
	TSQ	VRSH
	TOV	RVSAR		# BYPASS RESCALING IF OVERFLOW IN
#			   	  EITHER 2ND STEST OR ALS 1 6K10,
	STO	6K8S,1		# OTHERWISE SHIFT LEFT OR RIGHT 1
	TIX	*-4,1		# 6K8,6K9,6K10 AND P MATRIX
	AXT	7,1
	CLA	P11,1
	TSQ	VRSH
	STO	P11,1
	CLA	P31,1
	TSQ	VRSH
	STO	P31,1
	TIX	*-6,1
RVSAR	CLZ	S17		# IS FILTER INIT. REQUESTED
	ALS	3
	TMI	PINIT
	TRA	FLTRX
PINIT	AXT	7,1		# INITIALIZE P MATRIX AND FILTER
	CLZ	P11,1		# CONSTANTS
	CLZ	P31,1
	CLA	6K8,1
	STO	6K8S,1		# THIS ALSO ZEROES 6K6S
	
# Page 39
	TIX	PINIT+1,1
	CLA	6K2
PAD	STO	P11
	STO	P22
	CLA	6K4
	STO	P33
	STO	P44
	CLZ	MU19		# CLEAR MARK COUNTER
	CLZ	DEL45		# MAKE RANGE THE FIRST UPDATE
FLTRX	TSQ	EXEC
	TRA	LMORB
#
#		MATRIX MULTIPLY SUBROUTINE
#		PERFORMS C = A(T)*B(T) WHERE (T) INDICATES THE
#		TRANSPOSE OPERATION, EITHER WITH TR1 = ST0 A11
#		WHERE A11=ADDRESS OF 1ST ELEMENT OF A, TR2 = STO
#		B11, A = STO C11, TR4 = NO. OF COLUMNS IN A,
#		TR5 = NO. OF ROWS IN A, TR6 = NO. OF ROWS IN B,
#		THE RESULT MATRIX C WILL HAVE TR4 ROWS AND TR6
#		COLUMNS, ALL MATRICES ARE ASSUMED TO BE STORED
#		BY ROWS IN SEQUENTIAL LOCATIONS BEGINNING WITH
#		A11, A12, ..., A21, A22, ..., ETC.
MXM	STQ	PP		# SAVE RETURN ADDRESS
	STO	TR3		# STORE ST0 C11 IN TR3
	SUB	1B17
	STO	RREX2		# VARIABLE MATRIX ELEMENT STORE
	CLZ	I
R3	CLA	TR2
	SUB	1B4		# FORM MPY FROM STO
	STO	RREX1		# VARIABLE MULTIPLY
	CLZ	J
	CLA	DLSC		# (D24)
	STO	TI		# TEMP. STORAGE TO SAVE D24
	TSQ	EXEC
	CLA	TI
	STO	DLSC		# RESTORE D24
R2	CLA	TR1

# Page 40
	ADD	I
	ADD	STOCOM		# FORM CLA FROM STO
	STO	RREX		# VARIABLE CLA
	CLA	RREX2
	ADD	1B17		# INCREMENT STO INSTRUCTION
	STO	RREX2
	CLZ	K
	CLZ	TR8		# TEMP. SUM
R1	TRA	RREX
	TIX	*+2,1
	TRA	R3
	TIX	R1,1
	TRA	R2
#		TEST FOR VARIABLE SCALING OF FILTER
STEST	STO	VRSH+1
	STQ	SREX3
	CLA	RR		# B22
	MPR	RR		# 22+22=44
	MPY	6K9S
	LLS	10
	TSQ	VRSH
	AXT	7,1
	CLA	P11,1
	TSQ	VRSH
	CLA	P31,1
	TSQ	VRSH
	TIX	*-4,1
	TRA	SREX3
LMORB2	SUB	5J		# QL-5J AT B23
	STO	QLTELE		# PERIC. ALT
	CLZ	TS7		# = VH SQ AT B26
	STO	VHSQ		# SAVE FOR ORB INS
	TSQ	EXEC
#
ORBLM	AXT	2,1
	CLA	VIX,1		# RESTORE REX INTO FILTER
	STO	REX,1		# SCRATCH MATRIX C AREA
	
# Page 41
	CLA	RX,1
	STO	R0X,1
	CLA	VX,1
	STO	V0X,1
	TIX	ORBLM+1,1
	TSQ	ORBPM		# COMPUTE LM ORBIT PARAMETERS
	CLA	AI
	SUB	5J
	ALS	1		# MPY BY 2
	SUB	QLTELE
	STO	QA		# LM APOFOCUS ALT. AT B23
	TSQ	EXEC
#
#
	CLZ	Y
	CLZ	VY0
	AXT	2,1
KINGK	CLA	RX,1
	STO	RIX,1		# SAVE R FOR ORBIT INS.
	MPR	WCX,1
	ALS	1
	ADZ	Y
	STO	Y		# Y=(WCX)DOT(RX)
	CLA	VX,1
	STO	VIX,1		# SAVE V FOR ORBIT INS.
	MPR	WCX,1
	ALS	1
	ADZ	VY0
	STO	VY0		# VY0=(WCX)DOT(VX)
	CLA	WCX,1		# SET UP FOR CROSS
	COM			# PRODUCT SUBROUTINE
	STO	TS10,1		# WC X U1 = U1 X -WC
	CLA	U1X,1
	STO	TS4,1
	TIX	KINGK,1
	TSQ	CRSPRD
	TSQ	NORMV		# V1 VECTOR TO TSB
	
# Page 42
	TSQ	CRSPRD
	CLZ	TS3
	CLZ	TS4
	AXT	2,1
	CLZ	TS10,1
	STO	V1X,1		# V1 AT 1
	MPR	A31,1
	ADD	TS4		# TS4 = V1 DOT ZB AT B2
	STO	TS4
	CLZ	TS14,1
	ALS	1
	STO	W1X,1
	CLA	A31,1
	MPR	U1X,1
	ADD	TS3
	STO	TS3		# TS3 = U1 DOT ZB AT B2
	TIX	*-12,1
	TSQ	ARCTAE
	STO	XI
	TSQ	EXEC		# END OF LEM ORB PAR BRANCH
#
#	GUIDANCE MODE CHECK
#
GM	CLA	S10
	ADD	5B3
	ABS
	TMI	DXFR1		# TPI SEARCH
	ADD	1B2
	TMI	*+5
	CLZ	TDEL		# TDEL=0
	CLA	ORBRET		# =TRA DX10P
	STO	TSEX		# SET UP RETURN FROM NORTON
	TRA	NORTON+5
#		CSI,CDH,TPI EXECUTE, OR EXT DV
	CLA	TIG		# COMPUTE TDEL FOR
	SUB	TA1		# CSI, CDH, OR TPI(S10=4)
	ALS	5
	
# Page 43
	STO	TDEL
DXFR1	CLA	TDEL
	LRS	5
	ADD	TA1
	STO	TIG
	CLZ	TDEL		# TDEL = OR GTR 0 AFTER TR CALC
	TMI	*+2
	STO	TDEL
	ADD	6J
	STO	TR		# TIME UNTIL RENDEZVOUS (TPI)
	CLA	TDEL
DXFR10	TSQ	NORTON
DX10P	STO	RF		# PRED. BURNOUT ALTITUDE
	ADD	2K14
	STO	P
	CLZ	RADOT
	CLZ	VPY
DXFRR5	CLZ	RIX,1		# R5 STORE
	STO	R5X,1
	CLZ	VIX,1
	STO	TS14,1
	STO	V5X,1		# V5 STORE
	MPR	WCX,1
	ALS	1		# TO 13
	ADZ	VPY		# VPY = V5 DOT WC
	STO	VPY
	CLZ	TS10,1
	STO	U1X,1		# U1 STORE
	MPR	V5X,1		# RADOT = R5 DOT U1
	ALS	1		# TO 13
	ADZ	RADOT
	STO	RADOT
	CLA	REX,1		# CSM POS AND VEL FOR
	STO	R0X,1		# ELLIPSE PREDICTOR
	CLA	VEX,1		# AND ORBIT PARAMETERS
	STO	V0X,1
	TIX	DXFRR5,1
	
# Page 44
	TSQ	NORMV
	CLA	TS13
	STO	VHA
	TSQ	EXEC
ORBIT3	TSQ	ORBPM		# CSM ORBIT PARAMETERS
	CLA	TB
	SUB	TCSM
	ADD	TDEL		# +TIME INC. TO DXFR
	TMI	*+2
	SUB	TCSM
	TSQ	NORTON
DXFR13	CLZ	TS3
	CLA	RIX,1
	SUB	R5X,1
	STO	VIX,1		# RC-R5
	CLA	WCX,1
	STO	TS4,1
	CLA	U1X,1
	STO	TS10,1
	MPR	VIX,1		# U1 DOT (RC-R5)
	ADZ	TS3		# SCALE BOTH RX AND RZ
	STO	TS3		# AT 24 FOR ARCTAE
	TIX	DXFR13+1,1
	TSQ	CRSPRD
	TSQ	NORMV
	CLZ	TS4
VRUP1	AXT	2,1
	CLA	TS10,1
	STO	V1X,1		# V1,NORM XPROD OF WC AND U1
	MPR	VIX,1
	ADZ	TS4
	STO	TS4		# RZ AT 24
	TIX	VRUP1+1,1
	CLA	1B1
	SUB	S10
	TMI	XDV-1		# EXT DELTA V
	ADD	6B3
	
# Page 45
	TMI	THEF		# O.I., CSI, CDH
	CLZ	28J1		# COMPUE TPI VELOCITY
	CLZ	28J2		# IN LOCAL VERTICAL COORD.
	CLZ	28J3
	AXT	2,1
DXFRA	CLA	V1X,1		# B1
	MPR	VGX,1		# B1+B13=B14
	ALS	1		# B13
	ADZ	28J1
	STO	28J1
	CLA	W1X,1		# B1
	MPY	VGX,1		# B1+B13=B14
	DVP	M1B1		# B13
	ADZ	28J2
	STO	28J2
	CLA	U1X,1		# B1
	MPY	VGX,1		# B1+B13=B14
	DVP	M1B1		# B13
	ADZ	28J3
	STO	28J3
	TIX	DXFRA,1
	TSQ	ARCTAE		# TLOS=ARCTAN(RX,RZ)
	STO	TLOS		# LINE OF SIGHT (DEDA)
	CLA	TR
	SUB	TDEL
	STO	T
	CLA	TB
	SUB	TCSM
	ADD	TR		# TIME INC. TPI TO REND.
	SUB	3J		# TARGET OFFSET
	STO	TI
	TSQ	EXEC
DXFR14	CLA	S10
	COM
	TMI	CSMT1		# TO ELLIPX
#
#		ORBIT INSERTION SECTION


# Page 46
#
	SUB	VY0		# S10 EQUALS 0, ORBIT INSERTION
	MPR	VY0
	ADD	VHSQ		# VH SQ
	TSQ	SQRTE
	STO	VHA		# B13
	CLA	4K5		# COMPUTE DESIRED BURNOUT
	SUB	RB		# ALTITUDE RATE
	MPY	4K4
	LLS	3
	STO	RFDOT
	SUB	4K6		# LIMIT RFDOT BETWEEN
	TMI	*+3		# 23J AND 4K6
	CLA	4K6
	TRA	*+5
	CLA	23J
	SUB	RFDOT
	TMI 	*+3
	CLA	23J
	STO	RFDOT
	CLA	DISC1		# IS ABORT OR ABORT STATE YES
	ALS	7
	TMI	*+3		# -- ABORT YES
	ADD	M1B1
	TMI	ORBI2		# -- ABORT STATE NO
	CLA	THETAF
	SUB	12J
	TMI	*+5		# -- CENTRAL ANGLE LESS THAN LIMIT
	CLA	10J		# SET NEW SLOPE AND OFFSET
	STO	7J		# VALUES FOR AL WHEN ABORT OR
	CLA	11J		# ABORT STAGE YES AND THE
	STO	4K10		# CENTRAL ANGLE LARGE
	CLA	1B1		# STOP PASSES OF NEW SLOPE/OFFSET
	STO	12J		# EQUALS 4 RAD AT B3
ORBI2	CLA	THETAF		# CALCULATE AL
	MPY	4K10
	ADD	7J
	
# Page 47
	STO	AL
	CLA	RB
	STO	RF
	LRS	1		# CHECK FOR LOW LIMIT OF AL
	ADD	8J
	SUB	AL
	TMI	CDH3+1
	ADD	AL
	TRA	CDH3		# AL LOW LIMIT BJ+RB/2
#
#		TERMINAL FOR CSI, CDH, EXT DV
	TSQ	EXEC	
XDV	CLA	TIG		# TEST FOR ULLAGE TIME
	SUB	7K1
	SUB	TA1		# IF TIME FOR ULLAGE, THEN
	TMI	XDV2		# FREEZE COORDINATE FRAME
XDV1	AXT	2,1
	CLA	28J3		# RADIAL COMPONENT
	MPR	U1X,1		# 13+1=14
	STO	DQSX,1
	CLA	28J2		# CROSSRANGE COMPONENT
	MPR	W1X,1
	ADZ	DQSX,1
	STO	DQSX,1
	CLA	28J1		# DOWNRANGE COMPONENT
	MPR	V1X,1
	SUZ	DQSX,1
	ALS	1		# TO 13
	STO	DVGXX,1		# VELOCITY TO GAIN
	TIX	XDV1+1,1
XDV2	AXT	2,1		# LOAD NDX FOR STEER/XDV
	CLA	S10		# O.I. EXIT TO STEERING
	SUB	1B3
	TMI	STEER4+1	# GO TO STEERING
XDV3	CLA	DVGXX,1		# INITIAL VG
	SUB	DQSX,1		# ACCUMULATED DELTA V
	STO	TS4,1
	
# Page 48
	STO	VGX,1		# B13
	TIX	XDV3,1
	TSQ	DPVMAG
	STO	VG		# VEL TO GAIN MAGNITUDE
	TRA	Q7		# GO TO STEERING
#
Q5	CLA	RFDOT		# GUIDANCE LAW
	STO	TS4		# SET FOR INDEXING
	CLZ	TS5
	CLA	RADOT
	STO	TS10
	CLA	VY0
	STO	TS11
	AXT	1,1
	TOV	*+1
	CLA	RD3DOT,1	# -2
	MPR	TBO		# 9-2=7
	LRS	1		# TO 8
	STO	TS1		# 1/2 AT 7
	CLA	TS4,1		# RFDOT OR ZERO
	SUB	TS10,1		# RDOT OR VY0
	STO	TS2
	MPY	1B3		# B16
	DVP	TBO		# 16-9=7
	SUZ	TS1		# R OR YD2DOT
	STO	TS0		# TEST FOR OVERFLOW
	CLZ	TS2		# SIGN IF OVERFLOW
	TSQ	OVFLT
	STO	RD2DOT,1
	CLA	SIXTH		# -2
	MPR 	RD3DOT,1	# -4
	MPR	TBO		# 5
	LRS	1		# TO 6
	ADD	RD2DOT,1	# +1/2 2DOT AT 6
	MPR 	TBO		# 15
	ALS	1		# TO 14
	STO	TS1
	
# Page 49
	CLA	TS10,1
	LRS	1		# TO 14
	ADZ	TS1
	MPR	TBO		# 23
	ADD	R,1
	STO	TS14,1		# RF OR YF
	TIX	Q5+8,1
	STO	RF		# 23
	STO	RB		# SAVE RF FOR ORBIT INSERT.
	SUB	5J		# -LUNAR RADIUS
	SUB	16J		# BURNOUT ALT ERROR
	STO 	TS14
	LDQ	5K20
	CLA	4K12
	SUB	AT
	TMI	*+3		# IF AT GT 4K12
	CLA	DEL2	
	TMI	*+2		# IF AT LE 4K12 AND DEL2=1
	LDQ	5K18
	STQ	RD3DTL		# RD3DOT LOWER LIMIT
	CLA	TBO
	MPR	TBO
	MPR	TBO		# TB CUBED
	STO	TS1		# 27
	AXT	1,1
GDLAW3	TOV	*+1
	CLA	TS14,1		# BURNOUT ERROR
	MPY	12B4		# 27
	LLS	2		# TO 25
	DVP	TS1		# -2
	ADZ	RD3DOT,1	# DESIRED ACCEL RATE
	STO	TS0		# TEST FOR OVERFLOW
	CLA	TS14,1
	TSQ	OVFLT
	STO	RD3DOT,1
	TMI	*+5
	SUB	5K14,1		# UPPER LIMIT TEST
	
# Page 50
	TMI	*+5
	CLA	5K14,1		# SET AT UPPER LIMIT
	TRA	LL3DOT+1
	SUB	RD3DTL,1	# LOWER LIMIT TEST
	TMI	LL3DOT
GDLAW4	TIX	GDLAW3,1
	CLA	2K1		# 48
	MPY	1B1		# B49
	DVP	R		# 49-23-26
	SUZ	VHSQ		# VH SQ
	MPY	1B4		# B30
	DVP	R		# -ORBITAL RAD ACCEL AT 7
	ADZ	RD2DOT
	STO	RD2DOT		# CMD RAD ACCEL AT 7
	TSQ	EXEC
#
#		STEERING EQUATIONS.
#
STEER	CLA	21J
	SUB	H
	TMI	STEER1
	CLA	22J
	SUB	HDOT
	TMI	STEER1
	CLA	1B3		# =1024B13	COMMAND X-AXIS VERT
	STO	VG
	CLA	PMAX		# PSIP=1
	TRA	*+9
STEER1	AXT	1,1
	TOV	*+1
	CLA	RD2DOT,1	# PSIP AND PSIY COMPS
	LDQ	ZERO
	DVP	AT		# PSIP OR Y AT ZERO
	STO	TS0		# TEST FOR OVERFLOW
	CLA	RD2DOT,1	# SIGN IF OVERFLOW
	TSQ	OVFLT
	STO	TS10,1		# PSIP OR PSIY AT 0
	
# Page 51
	TIX	STEER1+1,1
	MPR	TS10
	COM
	ADD	PMAX
	STO	TS14		# 1-(PSIP)SQ
	TSQ	SQRTE
	STO	TS15
	CLA	TS11
	ABS
	SUB	TS15
	TMI	STEER3
	CLA	TS11
	TMI	*+3
	CLA	TS15
	TRA	*+3
	CLA	TS15
	COM
	STO	TS11
STEER3	CLA	TS11
	MPR	TS11
	COM
	ADZ	TS14
	TSQ	SQRTE
	STO	TS12
STEER4	TRA	XDV1		# COMPUTE DELTA V IN LOCAL VERT.
	CLA	TS10
	MPR	U1X,1
	STO	TS1
	CLA	28J1
OUT1	TMI	OUT		# IF 28J1 NEGATIVE
	CLA	TS12
	MPR	V1X,1
	ADZ	TS1
	STO	TS1
	CLA	TS11
	MPR	W1X,1
	ADZ	TS1
	
# Page 52
	MPY	VG
	LLS	1		# TO 13
	STO	VGX,1		# VELOCITY YET TO BE GAINED
	TIX	STEER4+1,1
Q7	AXT	2,1		# COMPUTE VELOCITY TO BE
	CLA	VDX,1		# GAINED COMPONENTS
	STO	VSMGX,1
	TIX	*-2,1
	AXT	2,1
	CLA	VGX,1
	MPY	A11,1
	LLS	1		# TO 13
	ADZ	VSMGX		# X-COMP OF TOTAL V TO BE GAINED
	STO	VSMGX
	CLA	VGX,1
	MPY	A21,1
	LLS	1		# TO 13
	ADZ	VSMGY
	STO	VSMGY		# Y-COMP OF TOTAL V TO BE GAINED
	CLA	VGX,1
	MPY	A31,1
	LLS	1		# TO 13
	ADZ	VSMGZ
	STO	VSMGZ		# Z-COMP OF TOTAL V TO BE GAINED
	CLA	MU8		# TEST IF ENG ON
	SUB	1B17
	TMI	*+4		# -- ENG OFF
	CLA	VG
	SUB	5K26
	TMI	*+5
	CLA	VGX,1
	MPY	1B1		# B14
	DVP	VG		# RESULT AT B1
	STO	A11BD,1
	TIX	Q7+5,1
	TSQ	EXEC
IDLE	TRA	TEST


# Page 53
OUT	CLA	TS12
	COM
	TRA	OUT1+2
OVFLT	TOV	*+3
	CLA	TS0
	TRA	EXIT		# EXIT WITH COMPUTED VALUE
	TMI	*+3
	CLA	PMAX		# POSITIVE LIMIT
	TRA	*+2
	CLA	NMAX
	TRA	EXIT
#
#		DISPLAY ROUTINE SOFT PORTION.
#
DSP1	TOV	*+1		# CL. O.F.
	CLZ	DSPF1		# H,HDOT MODE.
	TMI	*+2		# -- IS INITIALIZE
	TRA	DSPLY		# TO COUNTER CHECK. (HARD)
	CLA	H
	STO	POUT
	CLA	HDOT
#		Q REGISTER DOES NOT NEED TO BE ZERO
#		SINCE DVP K55 IS AT WORST A LEFT
#		SHIFT OF 2 AND THE ALT RATE REGISTER
#		IS ONLY 15 BITS LONG
	DVP	K55
	TRA	DSPLY1
DSP2CP	CLA	VY0		# OUT-OF-CSM PLANE VEL.
	LRS	17		# SET SIGN OF Q AND USE
	LLS	17		#	UP TIME
	STQ	TS10		# SAVE SIGN
	ABS
	DVP	VY0FS		# =FULL-SCALE VALUE(200 FPS)
	TOV	*+2
	TRA	*+2
	CLA	PMAX
	ADZ	TS10		# VY0 IN SIGN-MAGNITUDE
	
# Page 54
	TRA	DSPLY3-1	# TO OUTPUT,(HARD)
#
#		EXECUTIVE PART 2. (BRANCH 50)
#		START EXEC2
#
EXEC7	CLA	IDRP
	SUB	ID		# TEST FOR AGS INITIALIZE ID
	TMI	EXECM2
EXEC2	CLA	BR1		# SET NAV BRANCH
	STO	BRANCH
	CLZ	DDF		# DEDA DATA FLAG.
	TMI	NEWDD
EXECM	CLZ	DEL31		# TEST FOR DOWNLINK DATA
	TMI	EXEC7
EXECM1	CLA	S0
	SUB	3B3
	TMI	EXECA		# S0-3(--IS INER. REF)
	SUB	1B3		
	TMI	EXEC6		# S0-4(--IS IMU ALIGN)
	SUB	1B3
	TMI	TMIE1		# RESET TM
	SUB	1B3
	TMI	EXECA		# S0-6(--IS ORB ALIGN)
	ADD	7B3		# S0+1
	TMI	INCMU7		# S0=7
CAL	CLA	DEL21		# CALIBRATE MODE
	TMI	*+2
	TSQ	EADICS		# IMU DIR COSINES
	TSQ	ATTERR		# COMPUTE ATTITUDE ERRORS
	AXT	2,1
	CLA	1K33		# -3
	MPY	EX,1		# 2
	LLS	12		# -3+2-12=-13
	ADZ	DAXREM,1
	STO	DAXREM,1	# -13
	CLA	1K34		# -15
	MPR	EX,1		# 2
	
# Page 55
	ADZ	1K1,1
	STO	1K1,1		# GYRO BIAS AT -13
	TIX	*-9,1
INCMU7	CLZ	MU7		# INCR. COUNTER
	ADD	1B17
	STO	MU7
	SUB	1K37		# ACCEL. CAL. DURATION
	ABS
	COM
	TMI	*+7		# + IS TIME FOR ACCEL CAL
	AXT	2,1
	CLZ	SDVX,1
	MPR	1K36
	ADZ	1K19,1
	STO	1K19,1		# NEW BIAS CORRECTION
	TIX	*-4,1
	CLA	MU7
	SUB	1K30
	TMI	EXECA
	CLZ	S0		# CAL COMPLETE, SET ATT HOLD
EXECA	CLZ	DAXA		# ZERO ALIGNMENT INCREMENTS
	CLZ	DAYA
	CLZ	DAZA
	TRA	TMIE1		# RESET TM
NEWDD	CLA	STOCOM		# EQU TO STORE
	ADD	ADST		# DEDA ADDRESS
	STO	VRSH+1		# SET UP STORE INSTRUCTION
	CLA	DD		# DEDA DATA
	TSQ	VRSH		# STORE DATA
	CLA	BR1		# PROTECT BRANCH FROM DEDA
	STO	BRANCH
	CLA	DLWNLC		# PROTECT DLWNL
	STO 	DLWNL		# FROM DEDA ENTRY
	CLA	ADST
	SUB	1B9		# S0 ADDRESS
	TMI	EXECM
	SUB	1B17
	
# Page 56
	TMI	EXEC3		# NEW WD IS S0
	SUB	10B17
	TMI	EXECM		# NEW WD BTWN S0PS13
	SUB	1B17
	TMI	LUNAZ		# NEW WD IS S13
	SUB	1B17
	TMI	*+2		# NEW WD IS S14
	TRA	EXECM
	CLA	S14		# NEW WD IS S14
	SUB	2B3
	STO	DEL32		# ENABLE DL IF S14=1
	TMI	EXECM2+2
	COM
	TMI	EXECM1		# -- S14=3
EXECM2	CLA	IC1BR		# SET IC1 BRANCH
	STO	BRANCH
	CLA	IDAI		# AGS INITIALIZE ID
	STO	ID
	TRA	EXECM1
EXEC3	CLA	S0
	ADD	1B3		# NEG IF S0=7
	TMI	MABEE
	SUB	7B3
	TMI	EXECA
	CLA	DEL21		# CALIBRATE I.C.
	TMI	MABEE
	CLA	3B3		# IMU ALINE FOR 2SECS.
	STO	S0
	STQ	DEL6
MABEE	AXT	6,1
	CLZ	SDVX,1		# ZERO MU7 AND DV SJMS
	CLA	A11,1
	STO	A11D,1
	TIX	*-3,1
	TRA	EXECA
EXEC6	CLZ	DEL6		# IMU ALINE.