.OBJ loader for Processing

.OBJ file often has a link to .MTL file, which contains material information such as texture, color and surface reflection. To use the material information, you need to add .MTL file to the project. Currently, OBJModel class supports only texture information. Texture file images (.jpg) should be added to your project too.

Future updates will include support for other material information.

• Polygons are not correctly rendered. What should I do?

The first thing you should make sure is what type of polygons your model is composed of. If it is made of quads, the correct option for drawMode() is POLYGON. If it is made of triangles, drawMode(TRIANGLES) still works. drawMode(TRIANGLES) is recommended for Processing BETA 85 because of some rendering bugs (shapes drawn as POLYGONS sometimes don't show up.) More detailed info is available here (discource: Libraries, Tools - New Libraries: OBJ Loader, Google Web API )

If the model still doesn't show up, please send me the Processing source code and .OBJ model files you are trying to render. tatsuyas@ucla.edu

• Texture is not correctly shown. What should I do?

To render texture, three files have to be added to your project: .OBJ file, .MTL file, texture image file.

OBJModel uses standard Processing functions to render models. Inside the library, texture image is stored as PImage object, which means that the texture image file format has to be supported by PImage. Currently it supports .jpg.

• I still have a problem with online execution

Hmm.. I updated the library so that it can load models files by relative path whereever a sketch program is located. It might still have a bug. Please send me the model file and the sketch program you have a problem with.

// .OBJ Loader
// by SAITO <http://users.design.ucla.edu/~tatsuyas> 
// Placing a virtual structure represented as mathematically 
// three-dimensional object.
// OBJModel.load() reads structure data of the object stored 
// as numerical data.
// OBJModel.draw() gives a visual form to the structure data.
// processing standard drawing functions can be used to manipulate
// the visual form to create deep visual experiences.
// Created 20 April 2005
import saito.objloader.*;
import processing.opengl.*;
OBJModel model;
float rotX;
float rotY;
               
void setup()
{ 
   size(400, 400, OPENGL);
   model = new OBJModel(this, "dma.obj");
}

void draw()
{
   background(51);
   noStroke();
   lights();
   
   pushMatrix();
   translate(width/2, height/2, 0);
   rotateX(rotY);
   rotateY(rotX);
   scale(20.0);
   model.drawMode(POLYGON);
   model.draw();
   popMatrix();
}
void keyPressed()
{
   if(key == 'a')
   model.enableTexture();

   else if(key=='b')
   model.disableTexture();
}
void mouseDragged()
{
   rotX += (mouseX - pmouseX) * 0.01;
   rotY -= (mouseY - pmouseY) * 0.01;
}

• Model transformation

// .OBJ Loader transformation
// by SAITO <http://users.design.ucla.edu/~tatsuyas>
// Placing a virtual structure represented as mathematically
// three-dimensional object.
// OBJModel.getVertex() allows accessing to each vertex
// OBJModel.setVertex() allows transformation of a model             
import saito.objloader.*;
OBJModel model;
OBJModel tmpmodel;
float rotX;
float rotY;
void setup()
{
   size(600, 600, P3D);
   model = new OBJModel(this, "dma.obj");
   tmpmodel = new OBJModel(this, "dma.obj");
   model.debugMode();
}
void draw()
{
   background(255);
   lights();
   pushMatrix();
   translate(width/2, height/2, 0);
   rotateX(rotY);
   rotateY(rotX);
   scale(30.0);
   
   // renders the temporary model
   tmpmodel.draw();
 
  popMatrix();
   
  animation();
}
// transformation parameter
float k = 0.0;
// transforms the orignal model shape and stores transformed shape 
// into temporary model storage
void animation(){
 
 for(int i = 0; i < model.getVertexsize(); i++){
   PVector orgv = model.getVertex(i);
   PVector tmpv = new PVector();
   tmpv.x = orgv.x * (abs(sin(k+i*0.04)) * 0.3 + 1.0);
   tmpv.y = orgv.y * (abs(cos(k+i*0.04)) * 0.3 + 1.0);
   tmpv.z = orgv.z * (abs(cos(k/5.)) * 0.3 + 1.0);
   tmpmodel.setVertex(i, tmpv);
  }
   k+=0.1;
}
void mouseDragged()
{
   rotX += (mouseX - pmouseX) * 0.01;
   rotY -= (mouseY - pmouseY) * 0.01;
}