The SPARQL endpoint can be accessed at: http://www.open-biomed.org.uk/sparql/endpoint/gxa

More information available at: http://www.ebi.ac.uk/efo/semanticweb/atlas

Query for all the experiments in the endpoint

PREFIX experiment: <http://www.ebi.ac.uk/efo/EFO_0004033>

SELECT * 
{ 
?x a experiment:
}

There are 5661 experiment in the repository set up on June 22, 2011. (Initially there were 2497 experiments in the repository set up on June 8, 2011)

SELECT count(distinct ?s) WHERE { ?s rdf:type <http://www.ebi.ac.uk/efo/EFO_0004033> }

What do we describe about an experiment?

describe <http://www.ebi.ac.uk/gxa/experiment/E-AFMX-1>

Which genes were studied in an experiment?

Max 500 top differentially expressed genes per experiment due to a limitation in the Atlas REST service

PREFIX experiment: <http://www.ebi.ac.uk/efo/EFO_0004033>
PREFIX gene: <http://www.ebi.ac.uk/efo/EFO_0002606>
PREFIX is_about: <http://purl.obolibrary.org/obo/IAO_0000136>

SELECT DISTINCT ?gene
{
<http://www.ebi.ac.uk/gxa/experiment/E-AFMX-10> is_about: ?x .
?x gene: ?gene
}

How many genes are available for an experiment?

Max 500 top differentially expressed genes per experiment due to a limitation in the Atlas REST service

PREFIX experiment: <http://www.ebi.ac.uk/efo/EFO_0004033>
PREFIX gene: <http://www.ebi.ac.uk/efo/EFO_0002606>
PREFIX is_about: <http://purl.obolibrary.org/obo/IAO_0000136>

SELECT COUNT(DISTINCT ?gene)
{
<http://www.ebi.ac.uk/gxa/experiment/E-AFMX-10> is_about: ?x .
?x gene: ?gene
}

You can find a lot gene expression results information. Each result set is identified using a blank node.

Compare with information retrieved by the Restful service: http://www.ebi.ac.uk/gxa/api?experiment=E-AFMX-10&indent

How can we find out the list genes studied by each experiment?

PREFIX experiment: <http://www.ebi.ac.uk/efo/EFO_0004033>
PREFIX gene: <http://www.ebi.ac.uk/efo/EFO_0002606>
PREFIX is_about: <http://purl.obolibrary.org/obo/IAO_0000136>

SELECT DISTINCT ?experiment ?gene
{
?experiment a experiment: .
?experiment is_about: ?x .
?x gene: ?gene
}

LIMIT 100

How can we find out the list of experiments that studied a gene?

PREFIX experiment: <http://www.ebi.ac.uk/efo/EFO_0004033>
PREFIX gene: <http://www.ebi.ac.uk/efo/EFO_0002606>
PREFIX is_about: <http://purl.obolibrary.org/obo/IAO_0000136>

SELECT DISTINCT ?experiment
{
?experiment a experiment: .
?experiment is_about: ?x .
?x gene: <http://www.ensembl.org/Gene/Summary?g=ENSRNOG00000011751>
}

Which genes/experiments were overexpressed in liver?

PREFIX experiment: <http://www.ebi.ac.uk/efo/EFO_0004033>
PREFIX gene: <http://www.ebi.ac.uk/efo/EFO_0002606>
PREFIX is_about: <http://purl.obolibrary.org/obo/IAO_0000136>
PREFIX discretized_differential_expression: <http://www.ebi.ac.uk/efo/EFO_0004034>
PREFIX experimental_factor: <http://www.ebi.ac.uk/efo/EFO_0000001>

SELECT DISTINCT ?experiment ?gene
{
?experiment a experiment: .
?experiment is_about: ?x .
?x gene: ?gene .
?x experimental_factor: "liver" . 
?x discretized_differential_expression: "UP" 
}