Jedi Academy.ahk - jedi-academy-ahk - Project Hosting on Google Code

‹r3

Source path: svn/ trunk/ Jedi Academy.ahk

; set these the same as your actual JA configuration
; (these could be extracted from jaconfig.cfg in the future)
; cannot use Alt here! Hitting Alt in JA seems to cause movement (and other?) keys to sneak through AHKs hook
bind_moveForward := "w"
bind_moveLeft := "a"
bind_moveBack := "s"
bind_moveRight := "d"

bind_jump := "Space"
bind_crouch := "Shift"	; do not use Alt

bind_attack := "LButton"
bind_altAttack := "RButton"

bind_forcePush := "Ctrl"
bind_forcePull := "Alt"	; Alt seems okay here
bind_forceGrip := "o"
bind_forceMindTrick := "MButton"

bind_saberStyle := "l"

bind_lightSaber := "1"

specialBind_lungeAttack := "WheelDown"
specialBind_flipAttack := "WheelUp"
SetCapsLockState AlwaysOff
specialBind_cartWheelLeft := "CapsLock"
specialBind_cartWheelRight := "f"
specialBind_cartWheelForward := "v"

SetBatchLines 15	; the speed at which the script runs

/*
todo:
need to do some memory scanning to reliably set the haveAllSaberStyles variable
so that changing saber stances for the special moves will work reliably
no matter whether you went the 3 style route or switched to something else

also need to just consider the dual/saber & saberstaff stances in general :P

need a more reliable saberStyleStaticPtr

need a more intelligent/reliable mindtrick
	there's source code to Jedi Academy mods that probably lend insight to how mindtrick/etc works, for instance:
	http://www.google.com/codesearch?hl=en&q="typedef+struct+entityState_s"+jedi+show:PlqG3-Mp1So:SgofosJwKnY:TvUB2_Qc0Pg&sa=N&cd=1&ct=rc&cs_p=http://duelers.jk2files.com/duelers-ja-code.zip&cs_f=duelers-ja-code/JKA_mp(SDK)/codemp/game/q_shared.h#l2675


future ideas:
record avg. duration of each animation with a running sum, count, and average
determine various sequences of animations for each attack & determine their duration
determine frequency of these sequences if random (probably not too random, or 50/50 if anything, is my guess)
recording inflicted damage for these would yield the most effective attacks

automatically scan and identity nearby entities, turn to face, perform an action
and turn back all instantly (force pull a health pack, toss a saber, etc.)

some notes:
changing an entities position only works for animating items (try the grate fan in front of you in the free the prisoners level)
clearly some sort of code must be executed to truly move an item

setting a character's health to 0 causes them to completely freeze, stop firing at you etc.
at this stage if you touch them they will perform the actual death animation sequence,
they'll also be removed if unattended
*/

#SingleInstance force
#Include %A_ScriptDir%\memory management.ahk

jaWindow := "Jedi Knight"
jaProcessName := "jasp.exe"

; pointers
entityArrayStaticPtr := 0x00C2A18C
entityArrayOffset1 := 0x40
entityArrayOffset2 := 0x0
entityStructSize := 0x4E4

;forceValueStaticPtr := 0x019A7EA0	; actually non-static but seems reliable (so far)
;forceValueOffset1 := 0x1250

idUnderCursorStaticPtr := 0x00C91A18
idUnderCursorOffset1 := 0x4834
idUnderCursorOffset2 := 0x0

; this is indeed static, but it's no good, I've had it fail on me
saberStyleStaticPtr := 0x2070561c

SABERSTYLE_FAST := 1
SABERSTYLE_MEDIUM := 2
SABERSTYLE_STRONG := 3

; they default to 4 bytes
ENTITY_POS_X := 0x18
	ENTITY_POS_X_TYPE := "Float"
ENTITY_POS_Y := 0x1C
	ENTITY_POS_Y_TYPE := "Float"
ENTITY_POS_Z := 0x20
	ENTITY_POS_Z_TYPE := "Float"
ENTITY_LOOK_Y := 0x3C
	ENTITY_LOOK_Y_TYPE := "Float"
ENTITY_LOOK_X := 0x40
	ENTITY_LOOK_X_TYPE := "Float"
ENTITY_TYPE := 0xA0
	ENTITY_TYPE_TYPE := "Int"
ENTITY_ANIM := 0xC8
	ENTITY_ANIM_TYPE := "UInt"
ENTITY_UNKNOWN := 0x12E
	ENTITY_UNKNOWN_TYPE := "Int"
	ENTITY_UNKNOWN_BYTES := 2
ENTITY_HEALTH := 0x244
	ENTITY_HEALTH_TYPE := "UInt"

; it's more than just this... a char can have a value of 0 here and NOT be mindtricked, like pretty much all
; the chars in the mission where you've been captured... hm
ENTITY_MINDTRICKED := 0x2CC
	ENTITY_MINDTRICKED_TYPE := "UInt"

ENTITY_ITEM_EFFECT := 0x4D0
	ENTITY_ITEM_EFFECT_TYPE := "Int"
	ENTITY_ITEM_EFFECT_BYTES := 2

SELF := 0
BACKDROP := 1022

; some item types
ITEM_DETONATOR := 35
ITEM_TRIPMINE := 36

; confirmed
ANIM_FORCECHOKED := 1322
ANIM_KNOCKEDDOWN := 1220
ANIM_HANDSBEHINDBACK := 922

; animation performed can vary by type of saber, saber stance,
; and enemies saber and saber stance, and who knows what else
; the names should really be refactored to be more specific if/when this is determined
ANIM_FORCECHOKED_2 := 1320
ANIM_FORCEDRAINED := 1362
ANIM_SABERLOCK := 841 ; confirmed
ANIM_SABERLOCK_2 := 848
ANIM_SABERLOCK_3 := 849
ANIM_SABERLOCK_4 := 742	; confirmed; with guy with dual sabers?
ANIM_SABERLOCK_5 := 838 ; confirmed; uh... single saber vs. single saber? dunno
ANIM_SABERLOCK_6 := 792 ; dual sabers vs. dual sabers?

ANIM_FORCEBLOCK := 1330
ANIM_FORCEBLOCK_2 := 1332 ; maybe?

scriptStart := A_TickCount

; point at backdrop by default
idUnderCursor := BACKDROP

InitDebugGUI()

#IfWinActive Jedi Knight
Hotkey %bind_moveForward%, label_moveForward
Hotkey %bind_moveLeft%, label_moveLeft
Hotkey %bind_moveBack%, label_moveBack
Hotkey %bind_moveRight%, label_moveRight

Hotkey ~%bind_moveForward% Up, label_moveForward_release
Hotkey ~%bind_moveLeft% Up, label_moveLeft_release
Hotkey ~%bind_moveBack% Up, label_moveBack_release
Hotkey ~%bind_moveRight% Up, label_moveRight_release

Hotkey %specialBind_lungeAttack%, label_lungeAttack
Hotkey %specialBind_flipAttack%, label_flipAttack
Hotkey %specialBind_cartWheelLeft%, label_cartWheelLeft
Hotkey %specialBind_cartWheelRight%, label_cartWheelRight
Hotkey %specialBind_cartWheelForward%, label_cartWheelForward

Loop {
	CheckProcess(jaProcessName)

	IfWinNotActive %jaWindow%
		continue

	entityArrayPtr := ReadPtr(entityArrayStaticPtr) + entityArrayOffset1
	entityArrayPtr := ReadPtr(entityArrayPtr) + entityArrayOffset2

	idUnderCursorPtr := ReadPtr(idUnderCursorStaticPtr) + idUnderCursorOffset1
	idUnderCursorPtr := ReadPtr(idUnderCursorPtr) + idUnderCursorOffset2
	pendingIdUnderCursor := ReadMemory(idUnderCursorPtr, "UInt", 4)
	if (pendingIdUnderCursor <> BACKDROP && pendingIdUnderCursor <> SELF)
		idUnderCursor := pendingIdUnderCursor

	EntityDebugText(0, "Own")
	EntityDebugText(idUnderCursor, "Char")

	SpecialMoves()

	; mindtricks only non-mindtricked entities,
	; and works continuously while the key is held down
	if (GetKeyState(bind_forceMindTrick, "p")) {
		awareOfPlayer := GetPropI(idUnderCursor, "ENTITY_MINDTRICKED") <> 0
		if (awareOfPlayer || InStandingAnim(idUnderCursor) && InInitialPosition(idUnderCursor))
			SendEvent {%bind_forceMindTrick%}
	}
	; screwing around with a quick force grip floor smash,
	; doesn't work reliably
	else if (GetKeyState(bind_forceGrip, "p")) {
		enemyAnim := GetPropI(idUnderCursor, "ENTITY_ANIM")
		if ( enemyAnim = ANIM_FORCECHOKED || enemyAnim = ANIM_FORCECHOKED_2 ) {
			MouseMove, 0, 5000, 1, R
			Sleep 100
			MouseMove, 0, 5000, 1, R
			Sleep 100


			MouseMove, 0, -5000, 1, R
			Sleep 100
			MouseMove, 0, -5000, 1, R
			Sleep 100
		}
	}

	Gui Submit, NoHide
	; instant death to whatever character you look at with this (friendlies too atm)
	if (killTarget) {
		isChar := GetPropI(idUnderCursor, "ENTITY_ANIM") <> 0
		if (isChar && GetPropI(idUnderCursor, "ENTITY_HEALTH") <> 0)
			SetPropI(idUnderCursor, "ENTITY_HEALTH", 0)
	}

	;forceValuePtr := ReadPtr(forceValueStaticPtr) + forceValueOffset1
	;forceValue := ReadMemory(forceValuePtr, "Char", 1)

	AnimationReaction(ANIM_FORCECHOKED, bind_forcePull)
	AnimationReaction(ANIM_KNOCKEDDOWN, bind_jump)

	/*
	AnimationReaction(ANIM_FORCEDRAINED, bind_forcePull)

	; a way to instantly break saber locks and such
	AnimationReaction(ANIM_SABERLOCK, bind_attack)
	AnimationReaction(ANIM_SABERLOCK_2, bind_attack)
	AnimationReaction(ANIM_SABERLOCK_3, bind_attack)
	AnimationReaction(ANIM_SABERLOCK_4, bind_attack)
	AnimationReaction(ANIM_SABERLOCK_5, bind_attack)
	AnimationReaction(ANIM_SABERLOCK_6, bind_attack)
	AnimationReaction(ANIM_SABERLOCK_7, bind_attack)
	*/

	;AnimationReaction(ANIM_FORCEPUSHED, bind_forcePush)
	;AnimationReaction(ANIM_FORCEPUSHED_2, bind_forcePush)

	;clipboard := SubStr(entityStructStart, 3)
}
return

updateDisplay:
	GuiControl Text, Display, %displayText%
	return

AnimationReaction(animation, reactionKey) {
	local ownAnimation
	ownAnimation := GetPropI(0, "ENTITY_ANIM")
	if (ownAnimation = animation) {
		Loop {
			IfWinNotActive %jaWindow%
				continue

			SendEvent {%reactionKey%}
			Sleep 10
			ownAnimation := GetPropI(0, "ENTITY_ANIM")
			if (ownAnimation <> animation) {
				if (animation = ANIM_FORCECHOKED)
					SendEvent %bind_lightSaber%
				return true
			}
		}
	}
	return false
}

EntityDebugText(entityIndex, controlName) {
	global globalEntityIndex := entityIndex

	GuiControl Text, % controlName
		, % "Index: " . entityIndex
		. "`nAddress: " . EntityStructStart(entityIndex)
		. "`nHealth: " . GetProp("ENTITY_HEALTH")
		. "`nAnimation: " . GetProp("ENTITY_ANIM")
		. "`nX: " . GetProp("ENTITY_POS_X") . " Y: " . GetProp("ENTITY_POS_Y") . " Z: " . GetProp("ENTITY_POS_Z")
		. "`nLookX: " . GetProp("ENTITY_LOOK_X") . " LookY: " . GetProp("ENTITY_LOOK_Y")
		. "`nType: " . GetProp("ENTITY_TYPE") . " Distance: " . GetDist()
		. "`nUnknown: " . GetProp("ENTITY_UNKNOWN") . " Entity Item Effect: " . GetProp("ENTITY_ITEM_EFFECT")
		. "`nEntity Mind Tricked?: " . GetProp("ENTITY_MINDTRICKED")
}

; can't just use BlockInput to stop character movement because then we won't be able to know the real
; physical state of keys because BlockInput will block their release
HaltMovement() {
	global
	inSpecialMove := true

	SendInput {%bind_moveForward% Up}{%bind_moveLeft% Up}{%bind_moveBack% Up}{%bind_moveRight% Up}
	Sleep 100	; adjust based on game, but it will take a moment before the player really stops
}

RestoreMovement() {
	global
	if %bind_moveForward%Key
		SendEvent {%bind_moveForward% Down}
	if %bind_moveLeft%Key
		SendEvent {%bind_moveLeft% Down}
	if %bind_moveBack%Key
		SendEvent {%bind_moveBack% Down}
	if %bind_moveRight%Key
		SendEvent {%bind_moveRight% Down}

	inSpecialMove := false
}

DoProp(operation, entityIndex, property, value = "") {
	local ptr, byteNum
	ptr := EntityStructStart(entityIndex) + %property%

	byteNum := %property%_BYTES
	if (byteNum = "")
		byteNum := 4

	return MemoryOp(operation, ptr, %property%_TYPE, byteNum, value)
}

EntityStructStart(entityIndex) {
	global
	return entityArrayPtr + (entityIndex * entityStructSize)
}

GetPropI(entityIndex, property) {
	global MEMORYOP_READ
	return DoProp(MEMORYOP_READ, entityIndex, property)
}

GetProp(property) {
	global globalEntityIndex
	return GetPropI(globalEntityIndex, property)
}

SetPropI(entityIndex, property, value) {
	global MEMORYOP_WRITE
	return DoProp(MEMORYOP_WRITE, entityIndex, property, value)
}

SetProp(property, value) {
	global globalEntityIndex
	return SetPropI(globalEntityIndex, property, value)
}

GetDist() {
	; all variables are local
	thisX := GetProp("ENTITY_POS_X")
	thisY := GetProp("ENTITY_POS_Y")
	thisZ := GetProp("ENTITY_POS_Z")

	selfX := GetPropI(0, "ENTITY_POS_X")
	selfY := GetPropI(0, "ENTITY_POS_Y")
	selfZ := GetPropI(0, "ENTITY_POS_Z")

	deltaX := selfX - thisX
	deltaY := selfY - thisY
	deltaZ := selfZ - thisZ

	xyDistance := Sqrt(deltaX ** 2 + deltaY ** 2)
	xyzDistance := Sqrt(xyDistance ** 2 + deltaZ ** 2)
	return xyzDistance
}

MotionKeyPress(key) {
	local smallTickCount
	%key%Key := true
	if (inSpecialMove)
		return

	SendEvent {%key% Down}
	;smallTickCount := A_TickCount - scriptStart
	;GuiControl Text, %key%P, %key% pressed %smallTickCount%
}

; labels instead of HotKey declarations with :: because the :: style doesn't take variables :(
label_moveForward:
	MotionKeyPress(bind_moveForward)
return
label_moveLeft:
	MotionKeyPress(bind_moveLeft)
return
label_moveBack:
	MotionKeyPress(bind_moveBack)
return
label_moveRight:
	MotionKeyPress(bind_moveRight)
return

MotionKeyRelease(key) {
	local smallTickCount
	%key%Key := false
	if (inSpecialMove)
		return

	SendEvent {%key% Up}
	;smallTickCount := A_TickCount - scriptStart
	;GuiControl Text, %key%R, %key% released %smallTickCount%
}

label_moveForward_release:
	MotionKeyRelease(bind_moveForward)
return
label_moveLeft_release:
	MotionKeyRelease(bind_moveLeft)
return
label_moveBack_release:
	MotionKeyRelease(bind_moveBack)
return
label_moveRight_release:
	MotionKeyRelease(bind_moveRight)
return


InitDebugGUI() {
	global
	Gui +AlwaysOnTop
	Gui Add, Edit, R9 W500 vChar
	Gui Add, Edit, R9 W500 vOwn
	Gui Add, Edit, W500 v%bind_moveForward%P
	Gui Add, Edit, W500 v%bind_moveForward%R
	Gui Add, Edit, W500 v%bind_moveLeft%P
	Gui Add, Edit, W500 v%bind_moveLeft%R
	Gui Add, Edit, W500 v%bind_moveBack%P
	Gui Add, Edit, W500 v%bind_moveBack%R
	Gui Add, Edit, W500 v%bind_moveRight%P
	Gui Add, Edit, W500 v%bind_moveRight%R
	Gui Add, Edit, W500 vDisplay
	Gui Add, Checkbox, vkillTarget, Kill On Mouse Hover
	Gui Show, NoActivate x2200 y100, JA Debug
	SetTimer updateDisplay
}

SaberCycleCount(startStyle, endStyle) {
	local result
	if (! haveAllSaberStyles) {
		; only 2 styles to cycle through
		if (startStyle = endStyle)
			return 0
		else
			return 1
	}
	; 3 styles to cycle through

	; have them start at 0
	startStyle -= 1
	endStyle -= 1

	result := 3 - startStyle
	result := Mod(result, 3)
	result := result + endStyle
	result := Mod(result, 3)

	return result
}

SaberCycle(saberStyle) {
	local currentSaberStyle := ReadByte(saberStyleStaticPtr)
	cycleCount := SaberCycleCount(currentSaberStyle, saberStyle)
	returnCycleCount := SaberCycleCount(saberStyle, currentSaberStyle)
}

label_lungeAttack:
	key%specialBind_lungeAttack% := true
return
label_flipAttack:
	key%specialBind_flipAttack% := true
return
label_cartWheelLeft:
	key%specialBind_cartWheelLeft% := true
return
label_cartWheelRight:
	key%specialBind_cartWheelRight% := true
return
label_cartWheelForward:
	key%specialBind_cartWheelForward% := true
return

; NOTE: delays are going to be different when running at different frames per second!
; should be refactored for this
SpecialMoves() {
	global
	if (key%specialBind_lungeAttack%) {
		; single saber, fast style, lunge attack
		SaberCycle(SABERSTYLE_FAST)
		HaltMovement()
		SendEvent {%bind_crouch% Down}{%bind_moveForward% Down}{%bind_saberStyle% %cycleCount%}
		Sleep 50
		SendEvent {%bind_attack%}
		Sleep 50
		SendEvent {%bind_saberStyle% %returnCycleCount%}{%bind_moveForward% Up}{%bind_crouch% Up}
		RestoreMovement()
		key%specialBind_lungeAttack% := false
	}
	else if (key%specialBind_flipAttack%) {
		; single saber, medium style, flip attack
		; with functions to accurately & instantaneously turn the player we could
		; have one of these flip spin you 180 at the end to actually keep facing forward
		SaberCycle(SABERSTYLE_MEDIUM)
		HaltMovement()
		SendEvent {%bind_moveForward% Down}{%bind_jump% Down}{%bind_saberStyle% %cycleCount%}{%bind_attack%}
		Sleep 100		; maybe 50 when running at a better FPS
		SendEvent {%bind_saberStyle% %returnCycleCount%}{%bind_jump% Up}{%bind_moveForward% Up}
		RestoreMovement()
		key%specialBind_flipAttack% := false
	}
	else if (key%specialBind_cartWheelLeft%) {
		; single saber, fast/medium/strong style, cartwheel (left)
		HaltMovement()
		SendEvent {%bind_moveLeft% Down}
		Sleep 50
		SendEvent {%bind_jump% Down}{%bind_attack% Down}
		Sleep 50
		SendEvent {%bind_jump% Up}{%bind_moveLeft% Up}
		Sleep 1200
		SendEvent {%bind_attack% Up}
		RestoreMovement()
		key%specialBind_cartWheelLeft% := false
	}
	else if (key%specialBind_cartWheelRight%) {
		; single saber, fast/medium/strong style, cartwheel (right)
		HaltMovement()
		SendEvent {%bind_moveRight% Down}
		Sleep 50
		SendEvent {%bind_jump% Down}{%bind_attack% Down}
		Sleep 50
		SendEvent {%bind_jump% Up}{%bind_moveRight% Up}
		Sleep 1200
		SendEvent {%bind_attack% Up}
		RestoreMovement()
		key%specialBind_cartWheelRight% := false
	}
	else if (key%specialBind_cartWheelForward%) {
		; this one needs lots of work, specifically, reliable functions
		; for turning the player to face certain coordinates instead of
		; this unreliable & often faulty method
		HaltMovement()
		SendEvent {%bind_moveLeft% Down}

		MouseMove, 5000, 0, 0, R
		Sleep 50
		MouseMove, 5000, 0, 0, R

		SendEvent {%bind_jump% Down}{%bind_attack% Down}
		Sleep 50
		SendEvent {%bind_jump% Up}{%bind_moveLeft% Up}

		MouseMove, -5000, 0, 0, R
		Sleep 50 
		MouseMove, -5000, 0, 0, R

		RestoreMovement()
		Sleep 1150
		SendEvent {%bind_attack% Up}
		key%specialBind_cartWheelForward% := false
	}
}

; a couple temporary functions until I find a better method for determining
; when the player should mindtrick
InInitialPosition(entityIndex) {
	oPosX := GetPropI(entityIndex, "ENTITY_POS_X")
	oPosY := GetPropI(entityIndex, "ENTITY_POS_Y")

	SetFormat float, 0.0
	posX := oPosX + 0
	posY := oPosY + 0
	SetFormat float, 0.6

	; not the integer *type*, but rather, does the decimal portion = ".00000"
	posIsInteger := oPosX = posX && oPosY = posY
	; if the entity had moved, its position wouldn't be a perfect nice round integer
	return posIsInteger
}

InStandingAnim(entityIndex) {
	anim := GetPropI(entityIndex, "ENTITY_ANIM")
	return anim = ANIM_HANDSBEHINDBACK || 920 || 921
}

GuiEscape:
	WinClose
return

GuiClose:
	CloseHandle(processHandle)
ExitApp

Show details Hide details

Change log

r4 by Christopher.Galpin on Dec 03, 2008 Diff

Still just adding more comments/detail so
this can be a better example. Renamed
bind_forceChoke -> bind_forceGrip.

Go to:

Project members, sign in to write a code review

Older revisions

r3 by Christopher.Galpin on Jun 09, 2008 Diff

Clarified & added some comments.

r2 by Christopher.Galpin on Jun 09, 2008 Diff

Initial import.

All revisions of this file

File info

Size: 17829 bytes, 591 lines

View raw file