1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169

<?xml version="1.0" encoding="utf-8"?>
<mx:TileList xmlns:mx="http://www.adobe.com/2006/mxml">
	<mx:Script>
		<![CDATA[
			import mx.controls.listClasses.IListItemRenderer;
			import mx.collections.ArrayCollection;
			import mx.controls.listClasses.ListBase;
			
			public static var SELECTION_LINE_COLOR:Number = 0x000000;
			public static var SELECTION_LINE_THICKNESS:Number = 1;
			public static var SELECTION_FILL_COLOR:Number = 0x000000;
			public static var SELECTION_FILL_OPACITY:Number = .1;
			
			private var multipleSelectionAnchor:Point;
			private var isMultiSelect:Boolean = false;
			private var selectionBox:Sprite = new Sprite;
			private var ctrlKey:Boolean = false;
			private var shiftKey:Boolean = false;
			
			override protected function keyDownHandler(event:KeyboardEvent):void
			{
				if (event.keyCode == Keyboard.CONTROL)
				{
					ctrlKey = true;
				}
				if (event.keyCode == Keyboard.SHIFT)
				{
					shiftKey = true;
				}
				
				super.keyDownHandler(event);
			}
			
			override protected function keyUpHandler(event:KeyboardEvent):void
			{
				if (event.keyCode == Keyboard.CONTROL)
				{
					ctrlKey = false;
				}
				if (event.keyCode == Keyboard.SHIFT)
				{
					shiftKey = false;
				}
				
				super.keyUpHandler(event);
			}			
			
			override protected function mouseDownHandler(event:MouseEvent):void
			{
				super.mouseDownHandler(event);
				
				this.ctrlKey = event.ctrlKey;
				this.shiftKey = event.shiftKey;  
				
				if (event.target is mx.controls.listClasses.ListBaseContentHolder)
				{
					if (this.ctrlKey == false)
					{
						this.clearSelected();
					}
					startMultipleSelect(this.mouseX, this.mouseY);
				}
				
			}
			
			private function startMultipleSelect(xCoord:Number, yCoord:Number):void
			{
				isMultiSelect = true;
				multipleSelectionAnchor = new Point(xCoord, yCoord);
				this.addChild(selectionBox);
				
				this.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
				this.stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
			}
			
			override protected function mouseMoveHandler(event:MouseEvent):void
			{
				if (isMultiSelect)
				{
					drawSelectionBox();
					drawIndicators();
				}
				
				super.mouseMoveHandler(event);
			}
			
			override protected function mouseUpHandler(event:MouseEvent):void
			{
				super.mouseUpHandler(event);

				if (isMultiSelect)
				{
					isMultiSelect = false;
					multipleSelect();
				}
				
			}
			
			private function multipleSelect():void
			{
				var selected:ArrayCollection = getTilesForSelection();
				
				for each (var item:IListItemRenderer in selected)
				{
					this.selectItem(item, false, true);
				}

				this.selectionBox.graphics.clear();
				this.removeChild(this.selectionBox);
			}
			
			private function drawSelectionBox():void
			{
				this.selectionBox.graphics.clear();
				this.selectionBox.graphics.lineStyle(SELECTION_LINE_THICKNESS, SELECTION_LINE_COLOR);
				this.selectionBox.graphics.beginFill(SELECTION_FILL_COLOR, SELECTION_FILL_OPACITY);
				this.selectionBox.graphics.drawRect(this.multipleSelectionAnchor.x, this.multipleSelectionAnchor.y, this.mouseX-this.multipleSelectionAnchor.x, this.mouseY-this.multipleSelectionAnchor.y);
				this.selectionBox.graphics.endFill();
			}
			
			private function drawIndicators():void
			{
				this.clearIndicators();
				var index:Number = 0;
				
				for (var i:Number = 0; i < this.listItems.length; i++)
				{					
					for each (var displayObject:DisplayObject in this.listItems[i])
					{
						if (displayObject.hitTestObject(this.selectionBox) || isSelected(index))
						{ 
							this.drawItem(displayObject as IListItemRenderer, true);
						}
						index++;
					}
				}				
			}
			
			private function isSelected(index:Number):Boolean
			{
				var selected:Boolean = false;
				
				if (selectedIndices.indexOf(index) != -1)
				{
					selected = true;
				}
				return selected;
			}
			
			private function getTilesForSelection():ArrayCollection
			{
				var selected:ArrayCollection = new ArrayCollection;
				
				for (var i:Number = 0; i < this.listItems.length; i++)
				{					
					for each (var displayObject:DisplayObject in this.listItems[i])
					{
						if (displayObject.hitTestObject(this.selectionBox))
						{
							selected.addItem(displayObject);
						}
					}
				}
				
				return selected;
			}			
		]]>
	</mx:Script>
</mx:TileList>