1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152

package de.derhess.projects.air_flashToMaxMSP
{
	import com.bit101.components.InputText;
	import com.bit101.components.Label;
	import com.bit101.components.NumericStepper;
	import com.bit101.components.PushButton;
	import com.bit101.components.TextArea;
	import com.bit101.components.Window;
	import com.demonsters.debugger.MonsterDebugger;
	
	import flash.desktop.NativeApplication;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	
	import org.tuio.connectors.UDPConnector;
	import org.tuio.osc.OSCManager;
	import org.tuio.osc.OSCMessage;
	
	[SWF(width="500", height="280", frameRate="30", backgroundColor="#FFFFFF")]
	public class as3_flashToMaxMsp extends Sprite
	{
		//--------------------------------------------------------------------------
		//
		//  Class variables
		//
		//--------------------------------------------------------------------------
		
		//--------------------------------------------------------------------------
		//
		//  Variables
		//
		//--------------------------------------------------------------------------
		private var oscListener:SimpleOSCListener;
		private var oscManager:OSCManager;
		private var receiver:UDPConnector;
		private var sender:UDPConnector;
		
		//USer Interface
		private var txtAddress:InputText;
		private var numStepperSend:NumericStepper;
		private var txtTextData:InputText;
		
		//--------------------------------------------------------------------------
		//
		//  Initialization
		//
		//--------------------------------------------------------------------------
		public function as3_flashToMaxMsp()
		{
			super();
			// Air stuff
			this.stage.nativeWindow.visible = true;
			NativeApplication.nativeApplication.addEventListener(Event.EXITING,handleExiting); 
			
			// Start Debugging
			MonsterDebugger.initialize(this);
			MonsterDebugger.trace(this, "Hello Air!");

			// Set up OSC 
			oscListener = new SimpleOSCListener();
			receiver = new UDPConnector("127.0.0.1",9001,true);
			sender = new UDPConnector("127.0.0.1", 9000, false);
			oscManager = new OSCManager(receiver, sender,false);
			oscManager.addMsgListener(oscListener)
			oscManager.start();
			
			//set up gui
			createSendUI();
			createReceiverUI();
		}
		//--------------------------------------------------------------------------
		//
		//  Properties
		//
		//--------------------------------------------------------------------------
		
		//--------------------------------------------------------------------------
		//
		//  Additional getters and setters
		//
		//--------------------------------------------------------------------------
		
		//--------------------------------------------------------------------------
		//
		//  Methods
		//
		//--------------------------------------------------------------------------
		private function createSendUI():void
		{
			var sendPanel:Window = new Window(this,20,20,"Sending OSC Data");
			sendPanel.width = 150;
			sendPanel.height = 210;
			var labelSendAddress:Label = new Label(sendPanel,10,10,"OSC Address");
			this.txtAddress = new InputText(sendPanel,10,30,"/example/address",null);
			var labelSendData:Label = new Label(sendPanel,10,60,"OSC Data");
			this.numStepperSend = new NumericStepper(sendPanel,10,80,null);
			this.txtTextData = new InputText(sendPanel,10,110,"your text data",null);
			
			sendPanel.addChild( new PushButton(sendPanel,10,160,"send OSC Message",handler_click_sendOSCMessage));
		}
		
		private function createReceiverUI():void
		{
			var receiverPanel:Window = new Window(this,180,20,"Receiving OSC Data");
			receiverPanel.width = 300;
			receiverPanel.height = 210;
			
			var txtReceiver:TextArea = new TextArea(receiverPanel,10,10,"");
			txtReceiver.width = 280;
			txtReceiver.height = 170;
			txtReceiver.html = true;
			
			// Add the textArea to the oscListener for displaying the data from Max/Msp 
			oscListener.receiverText = txtReceiver;
		}
		//--------------------------------------------------------------------------
		//
		//  API
		//
		//--------------------------------------------------------------------------
		
		//--------------------------------------------------------------------------
		//
		//  Eventhandling
		//
		//--------------------------------------------------------------------------
		private function handler_click_sendOSCMessage(event:MouseEvent):void
		{
			var myMsg:OSCMessage = new OSCMessage();
			myMsg.address = this.txtAddress.text;
			myMsg.addArgument("s", this.txtTextData.text);
			myMsg.addArgument("i",this.numStepperSend.value);
			MonsterDebugger.trace(this,"-- Message send --");
			oscManager.sendOSCPacket(myMsg);
			MonsterDebugger.inspect(myMsg);
		}
		
		private function handleExiting(event:Event):void
		{
			MonsterDebugger.trace(this,"exit Application");
			receiver.close();
			oscManager.stop();
		}
		
		//--------------------------------------------------------------------------
		//
		//  Broadcasting
		//
		//--------------------------------------------------------------------------
	}
}