1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255

;;; eval-after-load.el --- `eval-after-load' by mode, map, hook

;; Author: ahei <ahei0802@gmail.com>
;; Keywords: eval-after-load, autoload
;; URL: http://code.google.com/p/dea/source/browse/trunk/my-lisps/eval-after-load.el
;; Time-stamp: <2011-04-28 15:41:47 Thursday by taoshanwen>

;; This  file is free  software; you  can redistribute  it and/or
;; modify it under the terms of the GNU General Public License as
;; published by  the Free Software Foundation;  either version 3,
;; or (at your option) any later version.

;; This file is  distributed in the hope that  it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR  A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You  should have  received a  copy of  the GNU  General Public
;; License along with  GNU Emacs; see the file  COPYING.  If not,
;; write  to  the Free  Software  Foundation,  Inc., 51  Franklin
;; Street, Fifth Floor, Boston, MA 02110-1301, USA.

;;; Commentary:
;;
;; This package make you can `eval-after-load' by modes, keymaps,
;; by    use    `eal-eval-by-modes',   `eal-eval-by-maps',    and
;; `define-key'  more convenient  use  function `eal-define-key',
;; `eal-define-key',    `eal-define-keys-commonly'.    For   more
;; details, see article http://emacser.com/eval-after-load.htm

;;; History:
;;
;; 2010-4-5
;;      * initial version 1.0.

;;; Code:

(eval-when-compile
  (require 'cl))

(defgroup eal nil
  "Package use `eval-after-load' technique."
  :prefix "eal-")

;;;###autoload
(defcustom eal-loadfile-mode-maps
  `(("cc-mode"         nil                    c-mode-base-map)
    ("cc-mode"         c-mode                 c-mode-map)
    ("cc-mode"         c++-mode               c++-mode-map)
    ("cc-mode"         java-mode              java-mode-map)
    ("cc-mode"         awk-mode               awk-mode-map)
    "lisp-mode"
    ("lisp-mode"       emacs-lisp-mode        emacs-lisp-mode-map)
    "help-mode"
    ("man"             Man-mode               Man-mode-map)
    "log-view"
    ("compile"         compilation-mode       compilation-mode-map)
    ("gud")
    ("lisp-mode"       lisp-interaction-mode  lisp-interaction-mode-map)
    "browse-kill-ring"
    ("simple"          completion-list-mode   completion-list-mode-map)
    ("inf-ruby"        inferior-ruby-mode     inferior-ruby-mode-map)
    "ruby-mode"
    ("cus-edit"        custom-mode            custom-mode-map)
    ("info"            Info-mode              Info-mode-map)
    ("psvn"            svn-log-edit-mode      svn-log-edit-mode-map)
    ("psvn"            svn-status-mode        svn-status-mode-map)
    ("psvn"            svn-info-mode          svn-info-mode-map)
    ("package"         package-menu-mode      package-menu-mode-map)
    "dired"
    "apropos"
    "emaci"
    "cflow-mode"
    ("psvn"            svn-log-view-mode      svn-log-view-mode-map)
    ("vc-svn"          vc-svn-log-view-mode   vc-svn-log-view-mode-map)
    ("log-view"        log-view-mode          log-view-mode-map)
    "diff-mode"
    ("sgml-mode"       html-mode              html-mode-map)
    "sgml-mode"
    "w3m"
    ("data-debug"      data-debug-mode)
    ("debug"           debugger-mode          debugger-mode-map)
    "text-mode"
    "color-theme"
    "woman"
    "doxymacs"
    "grep"
    "view"
    ("hi-lock"         hi-lock-mode           hi-lock-map)
    "autoconf"
    "tcl"
    "sgml-mode"
    "image-mode"
    "shell"
    "sql"
    "rhtml-mode"
    "senator"
    "org"
    "org-agenda"
    "python"
    ("python-mode"     nil                     py-mode-map)
    "groovy-mode"
    "nxml-mode"
    "perl-mode"
    "cperl-mode"
    "artist"
    "calendar"
    "outline"
    "google-maps-static"
    "flymake"
    "ezbl"
    "markdown-mode"
    "graphviz-dot-mode"
    ("speedbar"        speedbar-mode          speedbar-key-map)
    ("speedbar"        speedbar-mode          speedbar-file-key-map)
    ("yasnippet"       nil                    yas/keymap)
    ("yasnippet"       yas/minor-mode         yas/minor-mode-map)
    ("chart"           chart-mode             chart-map)
    ("recentf"         recentf-dialog-mode    recentf-dialog-mode-map)
    ("conf-mode"       conf-javaprop-mode     conf-javaprop-mode-map)
    ("conf-mode"       conf-space-mode        conf-space-mode-map)
    ("cua-base"        nil                    cua--rectangle-keymap)
    ("make-mode"       makefile-gmake-mode    makefile-gmake-mode-map)
    ("make-mode"       makefile-mode          makefile-mode-map)
    ("make-mode"       makefile-automake-mode makefile-automake-mode-map)
    ("sh-script"       sh-mode                sh-mode-map)
    ("auto-complete"   auto-complete-mode     ac-completing-map)
    ("auto-complete"   nil                    ac-mode-map)
    ("list-processes+" nil                    list-processes-mode-map)
    ("semantic-decoration-on-include" nil semantic-decoration-on-include-map)
    ("semantic-symref-list" semantic-symref-results-mode semantic-symref-results-mode-map))
  "*List used to find load file by mode or map.

Every element of list is or a list consisted by load file, mode and map,
or just one load file, or nil. If element is a list, and its last element is nil,
it will be ignored."
  :type 'alist
  :group 'eal)

;;;###autoload
(defun eal-eval-by-modes (modes fun)
  "Run `eval-after-load' on function FUN by MODES.

FUN will be called by `eval' with argument mode of MODES.
Example:
\(eal-eval-by-modes
 ac-modes
 (lambda (mode)
   (let ((mode-name (symbol-name mode)))
     (when (and (intern-soft mode-name) (intern-soft (concat mode-name \"-map\")))
       (define-key (symbol-value (am-intern mode-name \"-map\")) (kbd \"C-c a\") 'ac-start)))))"
  (if (listp modes)
      (eal-eval-by-symbols modes 1 fun)
    (eal-eval-by-symbol modes 1 fun)))

;;;###autoload
(defun eal-eval-by-maps (maps fun)
  "Run `eval-after-load' on function FUN by MAPS.

FUN will be call by `eval' with argument mode of MAPS."
  (if (listp maps)
      (eal-eval-by-symbols maps 2 fun)
    (eal-eval-by-symbol maps 2 fun)))

;;;###autoload
(defun eal-eval-by-symbols (symbols pos fun)
  "Run `eval-after-load' on function FUN by SYMBOLS.

FUN will be call by `eval' with argument mode of SYMBOLS. "
  (mapc
   `(lambda (symbol)
      (eal-eval-by-symbol symbol ,pos ,fun))
   symbols))

;;;###autoload
(defun eal-eval-by-symbol (symbol pos fun)
  "Run `eval-after-load' on function FUN by SYMBOL."
  (let ((file (eal-find-loadfile-by-symbol symbol pos))
        (form `(,fun ',symbol)))
    (if file
        (eval-after-load file form)
      (eval form))))

;;;###autoload
(defun eal-find-loadfile-by-mode (mode)
  "Find load file by mode MODE."
  (eal-find-loadfile-by-symbol mode 1))

;;;###autoload
(defun eal-find-loadfile-by-map (map)
  "Find load file by map MAP."
  (eal-find-loadfile-by-symbol map 2))

;;;###autoload
(defun eal-find-loadfile-by-symbol (symbol pos)
  "Find load file by symbol SYMBOL, its position is POS."
  (let* ((symbol-name (symbol-name symbol))
         (first
          (find-if
           (lambda (pair)
             (if (stringp pair)
                 (if (string= symbol-name (eal-get-name-by-loadfile pair pos))
                     pair
                   (let ((file (and (string-match "^\\(.+\\)-mode$" pair)
                                    (match-string 1 pair))))
                     (if file
                         (if (string= symbol-name (eal-get-name-by-loadfile file pos))
                             pair))))
               (if pair
                   (if (eq (nth pos pair) symbol)
                       (car pair)))))
           eal-loadfile-mode-maps)))
    (if (listp first) (car first) first)))

;;;###autoload
(defun eal-get-name-by-loadfile (file pos)
  "Get `symbol-name' by load file FILE and position POS."
  (concat file "-" (if (= pos 1) "mode" "mode-map")))

;;;###autoload
(defun eal-define-keys (keymaps key-defs)
  "Execute `define-key' on KEYMAPS by `eval-after-load' technique use arguments from element of list KEY-DEFS.

KEY-DEFS should be one list, every element of it is a list
whose first element is key like argument of `define-key', and second element is command
like argument of `define-key'."
  (eal-eval-by-maps
   keymaps
   `(lambda (keymap)
      (eal-define-keys-commonly (symbol-value keymap) ',key-defs))))

;;;###autoload
(defun eal-define-keys-commonly (keymap key-defs)
  "Execute `define-key' on KEYMAP use arguments from KEY-DEFS.

KEY-DEFS should be one list, every element of it is a list
whose first element is key like argument of `define-key', and second element is command
like argument of `define-key'."
   (dolist (key-def key-defs)
     (when key-def
       (define-key keymap (eval `(kbd ,(car key-def))) (nth 1 key-def)))))

;;;###autoload
(defun eal-define-key (keymap key def)
  "Execute `define-key' use arguments KEYMAP, KEY, DEF by `eval-after-load' technique.

*Note*: KEYMAP should be quoted, this is diference between argument of `define-key'."
  (eal-eval-by-maps
   keymap
   `(lambda (keymap)
      (define-key (symbol-value keymap) ,key ',def))))

(provide 'eval-after-load)

;;; eval-after-load.el ends here