1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285

[
=== About

Also Written In Brainfuck (awib) is an optimizing brainfuck
compiler, 100% written in brainfuck. Awib reads brainfuck source
code as input and writes compiled programs as output. Awib is
a cross-compiler with several different target platforms available.


=== Requirements

Awib will run smoothly in any brainfuck environment where:

   o) Cells are 8-bit or larger

   o) The read instruction ',' (comma) issued after end of
      input results in 0 being written OR -1 being written
      OR no change being made to the cell at all.

The vast majority of brainfuck environments meet these criteria.


=== Environment

Code compiled by awib will execute in an environment where:

   o) Cells are 8-bit wrapping integers.

   o) Issuing the read instruction ',' (comma) after
      end of input results in the current cell being
      left as is  (no-change on EOF).

   o) At least 2^16-1 = 65535 cells are available.

   o) Operating beyond the available memory, in either
      direction, results in undefined behaviour.


=== Usage

Run awib in your brainfuck environment of choice. Feed brainfuck
source code to awib as input and the compiled program will be
written as output.

Awib is a cross-compiler. The supported target platforms are
listed in table 1. By default, the target "386_linux" is chosen.

To specify a target platform, insert a line on the form "@TARGET"
(without the quotation marks and with "TARGET" suitably replaced)
at the very beginning of the source code you wish to compile.
Awib will then produce output accordingly.

 +----------------+--------------------------------------------+
 |   TARGET       |   Description                              |
 +----------------+--------------------------------------------+
 | 386_linux      | Linux on i386                              |
 +----------------+--------------------------------------------+
 | lang_c         | C programming language                     |
 +----------------+--------------------------------------------+
       Table 1 - Available target platforms


=== Optimizations

Awib is an optimizing compiler:

 o) Sequences of '-','<','>' and '+' are contracted into single
    instructions. E.g. "----" is replaced with a single ADD(4).

 o) Mutually cancelling instructions are reduced. E.g. "+++--<>>"
    is equivalent to "+>" and is compiled accordingly.

 o) Some common constructs are identified and replaced with single
    instructions. E.g. "[-]" is compiled into a single CLEAR-
    instruction.

 o) Loops known to never be entered are removed. This is the case
    for loops opened at the very beginning of a program (when all
    cells are 0) and loops opened immediately after the closing
    of another loop.

Mats Linander 2008-03-23
matslina (at) kth (dot) se
]

[..]>>>>>>>++>>>>+[>,[->+>+<<]>>[-<<+>>]+<+[-[>+++++[-<------->]+<-[-[
-[-[--------------[--[-->>+<<[>>-<++[-<--------->]+<[--[>+++++++++[-<+
+++++++++>]<[-]          ]]]]]]]]]]]>[-<<<->>>]<<<]>>>>[->++++++++++++
++++++++<<<<[              -]>>>+[-<,+[-<+<+>>]+<<->[-[---------[-[---
[>++++[-<---                ->]+<+[-----------[-[-[-[--------------[--
[>++[-<----      ----->      ]+<--[--[>+++++++++[-<++++++++++>]<[-]]]]
]]]]]]]]]]      ]+>[-<->      ]>>[->+<]<<<[->>>+>->+<[>-]>[>]<[-<<->>]
<<<<<]>>>      ]+>[<-]<[<      ]>[-<<<,>>>>]<<<<+[->+<]>[-<<[<]<<<+>>>
>[>]>]++      ++++++++++++      ++++++>>>>[-<<<<->>>>]<<<+++<<<[<]<<<-
>>>>[>]      >>[[->+>+<<]>[      -<+>]+>-[-[-[<->[-]]<[->>+++++++[->++
+++++<      ]++++++++++++++>      [->++>++>++>++>++>++>++>++>++>++>++>
++>++                              >++<<<<<<<<<<<<<<]>++++++++++>->+++
+++++                              ++++>+++++>--->>++++++++++++++++>->
+++++      ++>++++++++++++>++      ++>+++++++++++++++++++>+>+++++++++<
<<<<<      <<<<<<<<<<<]>]<[->      >+++++++[->+++++++<]++++++>[->++>++
>++>+      +>++>++<<<<<<]>+++      +++++++>->++++++++++++>+++++>--->+<
<<<<<      <<<]>]<[->>+++++++      [->+++++++<]+++++++++>[->+>+>+>++>+
+>++>      ++>++>++<<<<<<<<<]      >++>+++++++>+++++>--->++++++++++>++
+++++      >++++++++++++>++++      +++++++++++++++>+++++++++++++++++++
+++<<      <<<<<<<<<<]<<[->>+      >>-<<<<]>>[-<<+>>]>+>[<++++[->++++<
]>[          -]]<[-<+<<<<[<]          >[[-<+<+>>]<[>>[>]>>>>>[>]>+>[<-
]<[<]>[-<<[<]<[-]<<<<[<]<[-]+>>[>]>>>>>[>]>>+<]>-<<<[<]<<<<<[<]<-]>>[>
]>>          >>>[>]>>[[-]<<<          [<]<[-]>>[>]>>      ]<<+[<]<<<<<
[<]>]      <<<[[->>+<<]<]>>>[>      ]>>>>     >[>]<[-     <]<[-<<<<[<]
<<<<[      -]>>>>>[>]>>[-<<<[<      ]<<<       <+>>>>     >[>]>>]+>]>]
>>>[>      ]<[[-]<]<<<<-]<[-]<      <[[-       ]<]<<<     +[->>>>+<<<<
]>>>>      ->>>]<<<+[->>>>>>>+      <<<<<     <<]>>>>     >>>-+[[-<+>]
>+<]>      [-<<->>]<<[[->+>+<<      ]>[-<+>]++++++[->     -------<]+>-
[-[-[      -[--------------[--      [<+        ++[->-     ------<]+>-[
--[<-      >>+++++++[-<+++++++      +++++      +>]<++     [-]]]]]]]]]<
<>[-+      +++++[-<------->]+<      [-[-[      -[-[--            -----
-----      --[--[-------------      -----      ------             ----
-[-->      -<<<<<<<[->>>>+>+<<      <<<]>      >>>>[-     <<<<<    +>>
>>>]<      <<[->>>+>+<<<<]>>>>      [-<<<      <+>>>>     ]<<<[-    >>
>+>+<<      <<]>>>>[-<<<<+>>>      >]+<-[      +[-]>[     -]<]<-    --
[+++[-]      >>[         -]<      <]<----      ---[++     +++++[    -]
>>>[-]<<      <     ]     +      +++++++>      >>[-<<     <[-]<-    <-
--<<++>>>]         ]>[         -<<+++<+<<      [>>>-<     -]>>[     ->
>]<<+<<-----      ---[>      >>-<-]>>[           ->>               ]<<
+<<-[>>>-<-]>>[->>]<<<<+++++++++>>+++++++>[->+<]>[>>>>>+<<<<<[>>+<,[>-
]>[>]<[-<<->>]+<+[>-]>[>]<[-<<->>]<->+++++++++[-<---------->]+<-[>-]>[
>]<[->>>>>++++++++[-<++++++++>]<[->++++<]<[->+>-<<]>+[-<+>]+>-[<->[-]]
<[-<[-]<+>>]<<<<]+<--[>-]>    [>       ]<[->>>>+<[>-<[->>+<<]]>>[-<<+>
>]<<->[-<+<->++++++                        ++[->++++++++<]>[-<++++>]<-
>]<<<<]+++++++++    [-<                         ++++++++++>]<++++[-]>>
>>>+<[>-]>[>]<    <<[[->                            >>+<<<]>>[-]<<]>>>
[-<<<+>>>]<<<  >>[-<<<<   <<[                         -]<<------->>>>>
>]<<<<<<]]>        >>>[ -]>[-]<<<]<                    ]>[-<<<<<[->>+>
+<<<]>>[-   < <+      >>]<[->+>>+<<<]>[-           <+>   ]++++++++++++
++++[->>----  ----        ---- ----<<]>>+           [<<+ +++++++++++++
++[->>++++                  + +++++++++++             <<]+>>[-]]<-----
-[<[-]>++                    ++++[-]]<[->               >+<<]++++++>+>
[-<-<----                      --<+>]>>]                 <]>[-<<<<<[->
>+>+<<<]>>                      [-<<+>>                   ]<[->+>>+<<<
]>[-<+>]+                ++     ++++++                     +++++++[->>
-------                 ---     -----                -<<    ]>>+[<<+++
++++++                 +++     ++++ [->     >         ++++  ++++++++++
++<<]                 +>>    [-]]< -----[<[-]>        ++++ +[-]]<[->>+
<<]+                 ++++  >+>[-< -<-----<+>]>>         ]<]>[<<<++++>>
>->                   ]<] >[-<<< <<   [->>+>+<           <<]>>[- <<+>>
]<[  ->+          >>  +<<< ]>[- <+>]>---[<+++               >    +++[-
]+  >[           -]> ]>[<+++++ +++++++++++[-  >                 ------
-- --             ------<]>+> +<         [<<<                  +>>++++
+++           +   ++++++++[- >++++     +++++                  +++++++<
]>          [-]>  -<]>[-<<<   <[-]<--->>>]<                     ]]<]>[
<          <<++> >>->]<]>[      -<<<<<[->                        >+>+<
<         <]>>[ -<<+>>]<[                              ->+        >>+<
<      < ]>[-<+>]>-[<+>+          [-]+>[-                ]>]       >[<
+    +++ ++++++++++++[-            >-----                 ----     ---
--   --< ]>+>+<[<<<+>>               +++++                 ++++    +++
+++   +[ ->++++++++++     +            ++++ +<       ]      >[-    ]>-
<]>[  -< <<<[-]<->>>]    <                 ]]<]<<   [[-     >+<   ]>>+
<<]>  [- <+>]<<<[[-     >>     >+            <<<]>>>       >+<<  <<]>>
>[-< <<+  >>>]+>--     [<-    >++[-            ]]<[-<<[   ->>+> +<<<]>
>[-<<+>>  ]<<<<[-     >>>>+   >+<<<<<  ]>>       >>[-<<<<  +>>> >]+>--
--[----    ---[<     ->+++++  ++++++[- ]]]<[      -<- <[-]+ <-[>-<[->>
+<<]]>     >[-<<     +>>]<[-< <[-]]]]>>>] <[-]    >,+[ [-<+ >]>+<]>[-<
<->>]      <<]<<  < <[<<]<+<<+ >>>>>[<<<[- >>+    <<]<[- >> +<<]<[->>+
<<]<  [     ->>   + <<]>>>>>>>[-<<<<<<+>>>> >    >]<[->+<< <<<<<+>>>>>
>]+> -      ---  -- -[-[<->++++++++[-]]<[-<  <  >>+<[>-<[->> +<<]]>>[-
<<+>>]      <<-  >[ -<+<->++++    ++++[->+++ +  ++++<]>[-<++++ >]<->]<
<>>]>       ]<[  << [-<<->>>>      >+<<<]<<[ [-  >>+<<]>>>>-<<< <]>>>[
-<<-<        +>  >>  ]<<[[->>      +<<]>>>[- ]<< <]>>[-<<+>>]<<  <[->+
>>+<<     <] >>[ -<  <+>>]>>>[    -<<<+<<+>> >>>]<[-<<<<<+>>>>    >]<<
>>>++    +++  +++[-<  ++++++++>]<[->++++<]<  [->+>-<<]>+[-<+>]    +>-[
<->[-]   ]<[- <[-]<+>  >]<<<<<[->[-]>[-]>[  -< +<+>>]<[->+<]>>[  ->+<<
<+>>]>   [-<+  >]<<<<<   ]>>>>>]<<[[->>+<  <]>  >>+<<<]>>[-<<+> >]<[[-
>+<]>>+  <<]>[ -<+>]+>[    <->[-]]<<<>    >[-<+  >>>[>>]>[-]+  <<<[<<]
]>>]<<<<  >>+<  [>-<[->>+               <<]]>>[-   <<+>>]<<   ->[-<+<-
>++++++++  [->+  +++++++<]>[-       <++++>]<->]<<>          [>>+<]>[<]
<<[[->>+<<  ]>>   >+<<<]>>[-<<+>>]>[[-]<+>]<<<>>[->>      >[-]+<<<]<[-
]<[-]<[->+< ]<[    ->+<]>>>>>>>[-<<<<+>>> >]< <<<<<<<<  [<<]>+>[>>]>>>
[-<<<[<<]>->[>>     ]+++++++++++[->+++  +++>++  ++++++  ++>+++<<<]>+++
.>++++..---.++       +.<-----------.   >>-.<++  +.---  ----.----------
--.-.+++++++++        ++.----------   -.+++++++   +++ +++.-----------.
++.-.>.<--.++          +++++++++++   +++.-------  --- -------.++.+++++
+++.------.+  +        +++++++++   ++++.-.>+.---[ --- >+<]>.[-]<<[-]<[
-]>]<<<<<[<< ]>      [ <<[-[-[  [-]>>-<<]>>[-><<< <<< <<<+++++++++++++
+++++++[->+++>+      + >+++++ >+++++>++++++<<<<<] +++  +++++++>>----->
>++++++++++<<.      >+ ++++. >.<------.+>--.+++++++++ . <.+.<---.+++<.
>>>--.+.<-.+++      ++ .>--- --.-<<+++ ++++++++.----- -- ---->-.----<<
++.--<.>>>>>>+     +++ +++++[<<<<.>.+  .+.+++.>.<----. <- --.>.>>>>+++
+++[-<+++++++     +>] <.>++++++[-<--   ------>]<<<<<+++ ++ +++.>>>.<<<
+.---------.     +++ >->>>[->+>+<<]>  [-<+>]+>-[-[-[-[-[ -[ -[-[-[<->[
-]]<[-<<<<<     +++ ++++. >>++.--<<< +.>++++++.  ------- --- ---<--.+<
.>>>>>>>]>]    <[- <<+++ ++.----->++.-->]>]<[-<<  -.<<+++ +.+ .>--.++<
----.-<+++    ++. ++.>> ++.--<<-.------>>>++++.   --->+++. --- >]>]<[-
<<<++.--<   <+++ +++++ .--------<+.>>>>.<<<<--   .+<.>>>>> >>]> ]<[-<<
<++.--<    <+++  ++++  +++.----------<+.>>>>    .<<<<--.+ <. >>> >>>>]
>]<[-<   <<++.+ ++++. -.<-.+++++.-------.+   ++>--.<<++++ +.  ++. >>--
.--    <<-.---  ---<-.+<.>>>>>>>]>]<[-<<<  <<+++++++.>>+  +.  --< <+++
.----------<+. >>>>.<<<<--.+<.>>>>>>>]>] <[-<<<<-.<<+.>>  ++  ++.  --.
>++++++.<--.+  ++++.- ------.>--.<<+++++.+.<--.>>++++++++ .-  --.  <-.
>---.<<+++.-. ->++++++ ++.-------.+.------->>--.--<<<+.>>. +< <--  .+<
.>>>>>>>]>]<  [-<<<<<++ +++++.>>++.-- <<+.--------<+.>>>>.< < <<-  -.+
<.>>>>>>>]>< <-]<<<-.+++   ++.------ -.>++++.<<---.>+.>+++.<  ++   ++.
-----------. <<----------           --.>>>>.<<+++++++++++...  .-  ----
----.<<+++++ ++++++.<.>>>+         +++++++++++.+++++.>-.<<.> -.  -----
-------.++++ ++++.+++++.<++       ++++++.+.>>>+++.<<<<<.>>> --  ------
---.+++++.-- -----.>--.<<---      ------.++++++++++.>>--.<< <  ++.>>+.
>+++++.<++++ .<<--.<.>>>+++.++   +++.>-.<<----------.>-----   ------.<
<.<.[-]>[-]> [-]>[-]>[-]>[-]>>>> [<<++++++++++[->++++++++++   <]>+.-[-
-<+>>+<]>--.  [-]>[-<<<<<<<+>>> >>>>]<<<----------.+[->>>+   <<<]<<<<>
>>>+[++++++++ +[-<++++++++++>]+ <[-<<+<[>-]>[>]<[->>>[-]<<   <]<->>>]>
[-<+>>+<]<[->  +<]>]>[>++++++[ -<++++++++>]+<.[-]]<<<<+++   +++++++[-<
++++++++++>]>> >+[<++++++++++[ -<<+<[>-]>[>]<[->>>[-]<<<   ]<->>>]>[-<
+>>+<]<[->+<]>  ]>[>[-]++++++ [-<++++++++>]<.[-]]>[++++   +[-<++++++++
>]<.[-]>]<<<<<+ +++++++++[-<+ +++++>]<--.[-]>>>>>>>.[-   ]++++++++++.-
--------->]>[-]  >[-]+++++++ +++[->+++++++++++>+++>++   +++<<<]>++++.-
------------.+++ +++++++++++ +.+.---.----.>++.>--.++   +++++++++.<<+++
++++++++++++.>>>  +++++++++ +.[-]<[-]<[-]<[-]<]<<]>   >[->[>>]>[->>+<<
]>[->>+<<]>>>+[-< <[->>+<<] +>[->>+<<]+>>>+<[>-<[-   >>+<<]]>>[-<<+>>]
<<->[-<+<->++++++  ++[->++ ++++++<]>[-<++++>]<->]   <<>[>>+<]>[<]<<[[-
>>+<<]>>>+<<<]>>[-  <<+>>] >[[-]<+>]<<<>>]<<+>+>   +>+>+>+>+>+[<]>>->-
>>->->-<<<<<<<>>++  +++[- >+++++++++++<]<<<<<<[   <<]>>[[-<+<<+>>>]>[-
<<<+>>>]<<>+<-[-[-[  -[-[ -[-[-[-[[-]>-<]>[->+   +<]<]>[->>[>>]>>>[[[>
]>]>]<<<-<[->>+>>+<  <<< ]<[->>+>>+<<<<]>>[-<   <+>>]>[-<<+>>]<<<[-<<+
>>]>[->+<]>[-<++++++  ++ [-<++++++++>]<[->++   ++<]<[->+>-<<]>+[-<+>]+
>-[<->[-]]<[-<[-]<+>  > ]>>]<<+>>>>>>-<<[->   >>[>]>>>[>>>]>+<<<<[<<<]
<[<]<<]>[->>[>]>>>[>>   >]>>+<<<<<[<<<]<[<   ]<]<+>+>+[>]>>>[>>>]>[->>
>+<<<]>[->>>+<<<]<<+[  [<]<]<->>>[>>>]>[-   <<<+<[<<<]>+>>[>>>]>]>[-<<
<+<<[<<<]>>+>[>>>]>>]< <<<<[<<<]+[>>>]<[   ->>+<<]<[->>+<<]+++++++++++
+++++[-<+++++++++++++  +++>]<--[->+>+<<   ]+>>>>>+<[>-<[->>+<<]]>>[-<<
+>>]<<->[-<+<->++++++  ++[->++++++++<]   >[-<++++>]<->]<<[-<<->>]>[->+
<]>[-<<+<[>-<[->>+<<]  ]>>[ -<<+>>]<<   ->[-<+<->++++++++[->++++++++<]
>[-<++++>]<->]>>]<<<<   <[<<  <]<[<]<    <<[[[<]<]<]<<[<<]]<]>[->>[>>]
>>>[[[>]>]>]<<<->>++++   +++[-<<<<>>   > ++++++++[-<++++++++>]<[->++++
<]<[->+>-<<]>+[-<+>]+>   -[< ->[-]]< [ - <[-]<+>>]<<>>>>]<+++++++>+>>-
>->[>]>>>[>>>]+[<<<]<[[  [<    ]<]<]<[ [ [<]<]<]<<[<<]]<]>[-<+<<----->
-[<+>>+<-[>++++++++++++  ++   [-<<++++ + +++>>>>++++++++<<]>>-<<+<<---
--[>[>-]>[>]<[-<<[->>>+   <<  <]+>+>]+ < -<-]+++>[<+>>>>+<<<-[<+>>>>+<
<<-[<+>[->>>+<<<]]]]>->[  ->  -<]>[-<<+ > >]<<<]]<[->>>>+<<<<]++++++>>
[-<+>]>]<]>[-<+<<---->-[  <+  >>+<-[>+++ + ++++++++++[-<<++++++++>>>>+
+++++++<<]>>-<<+<<-----[  >[> -]>[>]<[-<<  [->>>+<<<]+>+>]+<-<-]+++>[<
+>>>>+<<<-[<+>>>>+<<<-[<   +>[->>>+<<<]]]] >->[->-<]>[-<<+>>]<<<]]<[->
>>>+<<<<]+++++>>[-<+>]>]   <]>[->++++<]<]>[ ->+++<<+<-[>-]>[>]<[->>-<<
]<+>>]<]>[->++++++<]<]>[   ->+++<<+<-[>-]>[ >]<[->>-<<]<+>>]<>>[->[>>]
>>>[[[>]>]>]<<<-<<>>>+++   +++++[-<++++++++  >]<[->++++<]<[->+>-<<]>+[
-<+>]+>-[<->[-]]<[-<[-]<+  >>]<<>>+[[[<]<]<  ]<<[<<]>]>]+++++++++[>+++
+++++++++++<-]>+.+[--<+>]   <+++++.+++++++.  ------.>+...++.---.......
.++.--.+++.---.+.-...++++   [-<+++>]<++.>..  .++++++++[-<---->]<.>....
.......<.>.+++++[-<---->]   <.>.+.-.<++++++  ++.[-].....>>>.-.........
......<++++++[->+++++++++   +++++<]>>>>-<<<  [->>>>++++++++[-<++++++++
>]<[->++++<]<[->+>-<<]>+[-  <+>]+>-[<->[-]   ]<[-<[-]<+>>]<<<]>>.<.<..
>>.<.<..+++++++.[-].......   >[-]>[-]>>>>+  <+<+<+<+<+<+<+<<<+++++++++
+[->++++++++++++++++++++++   >++++++++++++  +++++++++++++<<<+++++<++++
++++++++++++++>>]>>+++++<<   <<++++.+++++  +++.>>...<-.>>-.<<<-------.
>>>>..<<..<<+.>>+++.---...<  <++++.>-----  ----------.>...<+++++++++++
++++.>>>.<<<.>>++++++++++++  ++++++.<<<++  +++++++++++++.>>>>-[--<<+>>
]<<+.+++++++++.<<----------  -.>+[->>>++  +<<<]>>>+.<+++++++++++++++.-
--------.>+++++++++++++++++   ++.<<.<<++  +++++++++++++.>>.<<---------
-----.>>+[--<+>]<--.++[->++   <]>-.<++++  [-<+++++>]<+++.>>.<<+++++.>>
+++[--<+>]<+..-[->++<]>---.>  +++++++++  ++.<+++[--<+>]<.-..<[-]>[-]>>
[-]>[-]+<+<+<+<<<[<<]>>[<+>-   [-[-[-[-  [-[-[-[-[[-]<->]<[-++++++++++
+[->+++++>++++++++++++<<]>>+   +++.[-]<  ++.[-]<]>]<[-+++++++[->++++++
++<]>++.-.------[->++<]>.<+++  [-<+++++  >]<.[->>++<<]>>+.[-]>[>>]>[>]
+>+>+>->>.[-]<.[-]<<[<]<<[<<]   <]>]<[  -+++++++[->++++++++<]>++.-.---
---[->++<]>.<+++[-<+++++>]<.[   ->>++<  <]>>.[-]>[>>]>[>]+>+>+>->>.[-]
<.[-]<<[<]<<[<<]<]>]<[->+>-[-[  <+++++  ++++[-<+++++++++++++>]<+.[-<+>
>+<]++++++[-<++++++++++>]<++.[  -]>>--  ----[<<+>>>[-[-<<+>>]<-<<->>>]
<<[->>+<<]<[->>[-<+>]<<]>>]++++  ++++[  -<<++++++++++++++++>>]+<[[-<->
]<-.[-]>>-<]>>[<-<<-.[-]>>+++++  +<]<[  -<<-.[-]>>]>]<[.++++++++++++++
[->+++++++++++++++<]>++++++++.[  -]<]> ] <[+++++++[->++++++++<]>+.[-]<
]<]>]<[->+>-[-[<+++++++++[-<+++  +++++ + ++++>]<+.[-<+>>+<]++++++++++[
-<++++++++++>]<++.[-]>>------[<< +>>>[- [-<<+>>]<-<<->>>]<<[->>+<<]<[-
>>[-<+>]<<]>>]++++++++[-<<++++ + +++++++ ++++>>]+<[[-<->]<-.[-]>>-<]>>
[<-<<-.[-]>>+++++<]<[-<<-.[-] >>] >]<[>+ +++++++[-<+++++>]<.-[->++++++
<]>-------.[-]<]>]<[+++++++[ ->++ ++++++ +<]>+.[-]<]<]>]<[-++++++++++[
->+++++++++++++<]>+++++++.+ [---- --<++++ ++++++>]<++++++++++.[------>
+++++<]>+++++.-----[-----< +++>]<  +++++++ +.[-]]>]<[->+>-[<-]<[<]++++
[-<++++>]<[->++++++++<]+>> [-<<->- [->++<]> .[-]+++++++++.[-]]<<[->.++
[------------->++++<]>+.[- ]>+.[-] <<<]>]>]< [-++++++++++[->++++++++++
++++<]>---.+++[-----<+++++ + +++>] <----.++[- --------->+++<]>.+++++++
[--<+++++>]<.[-]+++++[->++  + + +< ]>[-<+++++ >]<+++.++++++++[--------
>++++<]>-.[-]<]>]<[->+>-[<-  ] <[  <]++++[-<+ +++>]<[->++++++++<]+>>[-
<<->-[->++<]>.[-]+.-]<<[>.[-  ]<   .>>>+.[- ] <<<-]>]>>>]<++++++++++[-
>++++++++++++++<]>---.+++[---    -  ---< + +  +++++++++>]<----.>++++++
++[-<++++>]<++[---------->+++<]>.++  ++++ +  [--<+++++>]<.[-]+++++[->+
++++<]>[-<+++++>]<+++.[-]<]<<]]